reserve p,q for Point of TOP-REAL 2;

theorem Th21:
  for cn being Real,q1,q2 being Point of TOP-REAL 2 st -1<cn & cn<
  1 & q1`2>=0 & q2`2>=0 & |.q1.|<>0 & |.q2.|<>0 & q1`1/|.q1.|<q2`1/|.q2.| holds
for p1,p2 being Point of TOP-REAL 2 st p1=(cn-FanMorphN).q1 & p2=(cn-FanMorphN)
  .q2 holds p1`1/|.p1.|<p2`1/|.p2.|
proof
  let cn be Real,q1,q2 be Point of TOP-REAL 2;
  assume that
A1: -1<cn & cn<1 and
A2: q1`2>=0 and
A3: q2`2>=0 and
A4: |.q1.|<>0 and
A5: |.q2.|<>0 and
A6: q1`1/|.q1.|<q2`1/|.q2.|;
  now
    per cases by A2;
    case
A7:   q1`2>0;
      now
        per cases by A3;
        case
          q2`2>0;
          hence thesis by A1,A6,A7,JGRAPH_4:79;
        end;
        case
A8:       q2`2=0;
A9:       now
            (|.q1.|)^2=(q1`1)^2+(q1`2)^2 by JGRAPH_3:1;
            then (|.q1.|)^2-(q1`1)^2>=0 by XREAL_1:63;
            then (|.q1.|)^2-(q1`1)^2+(q1`1)^2>=0+(q1`1)^2 by XREAL_1:7;
            then -|.q1.|<=q1`1 by SQUARE_1:47;
            then
A10:        (-|.q1.|)/|.q1.|<=q1`1/|.q1.| by XREAL_1:72;
            assume |.q2.|=-(q2`1);
            then 1=(-(q2`1))/|.q2.| by A5,XCMPLX_1:60;
            then q1`1/|.q1.|< -1 by A6,XCMPLX_1:190;
            hence contradiction by A4,A10,XCMPLX_1:197;
          end;
          |.q2.|^2=(q2`1)^2+0^2 by A8,JGRAPH_3:1
            .=(q2`1)^2;
          then |.q2.|=q2`1 or |.q2.|=-(q2`1) by SQUARE_1:40;
          then
A11:      q2`1/|.q2.|=1 by A5,A9,XCMPLX_1:60;
          thus for p1,p2 being Point of TOP-REAL 2 st p1=(cn-FanMorphN).q1 &
          p2=(cn-FanMorphN).q2 holds p1`1/|.p1.|<p2`1/|.p2.|
          proof
            let p1,p2 be Point of TOP-REAL 2;
            assume that
A12:        p1=(cn-FanMorphN).q1 and
A13:        p2=(cn-FanMorphN).q2;
A14:        |.p1.|=|.q1.| by A12,JGRAPH_4:66;
A15:        (|.p1.|)^2=(p1`1)^2+(p1`2)^2 by JGRAPH_3:1;
A16:        p1`2>0 by A1,A7,A12,Th18;
A17:        now
              assume 1= p1`1/|.p1.|;
              then (1)*|.p1.|=p1`1 by A4,A14,XCMPLX_1:87;
              hence contradiction by A15,A16,XCMPLX_1:6;
            end;
A18:        p2=q2 by A8,A13,JGRAPH_4:49;
            (|.p1.|)^2-(p1`1)^2>=0 by A15,XREAL_1:63;
            then (|.p1.|)^2-(p1`1)^2+(p1`1)^2>=0+(p1`1)^2 by XREAL_1:7;
            then p1`1<=|.p1.| by SQUARE_1:47;
            then (|.p1.|)/|.p1.|>=p1`1/|.p1.| by XREAL_1:72;
            then 1>= p1`1/|.p1.| by A4,A14,XCMPLX_1:60;
            hence thesis by A11,A18,A17,XXREAL_0:1;
          end;
        end;
      end;
      hence thesis;
    end;
    case
A19:  q1`2=0;
A20:  now
        (|.q2.|)^2=(q2`1)^2+(q2`2)^2 by JGRAPH_3:1;
        then (|.q2.|)^2-(q2`1)^2>=0 by XREAL_1:63;
        then (|.q2.|)^2-(q2`1)^2+(q2`1)^2>=0+(q2`1)^2 by XREAL_1:7;
        then q2`1<=|.q2.| by SQUARE_1:47;
        then
A21:    (|.q2.|)/|.q2.|>=q2`1/|.q2.| by XREAL_1:72;
        assume |.q1.|=(q1`1);
        then q2`1/|.q2.|> 1 by A4,A6,XCMPLX_1:60;
        hence contradiction by A5,A21,XCMPLX_1:60;
      end;
      |.q1.|^2=(q1`1)^2+0^2 by A19,JGRAPH_3:1
        .=(q1`1)^2;
      then |.q1.|=q1`1 or |.q1.|=-(q1`1) by SQUARE_1:40;
      then (-(q1`1))/|.q1.|=1 by A4,A20,XCMPLX_1:60;
      then
A22:  -(q1`1/|.q1.|)=1 by XCMPLX_1:187;
      thus for p1,p2 being Point of TOP-REAL 2 st p1=(cn-FanMorphN).q1 & p2=(
      cn-FanMorphN).q2 holds p1`1/|.p1.|<p2`1/|.p2.|
      proof
        let p1,p2 be Point of TOP-REAL 2;
        assume that
A23:    p1=(cn-FanMorphN).q1 and
A24:    p2=(cn-FanMorphN).q2;
A25:    |.p2.|=|.q2.| by A24,JGRAPH_4:66;
A26:    (|.p2.|)^2=(p2`1)^2+(p2`2)^2 by JGRAPH_3:1;
        then (|.p2.|)^2-(p2`1)^2>=0 by XREAL_1:63;
        then (|.p2.|)^2-(p2`1)^2+(p2`1)^2>=0+(p2`1)^2 by XREAL_1:7;
        then -|.p2.|<=p2`1 by SQUARE_1:47;
        then (-|.p2.|)/|.p2.|<=p2`1/|.p2.| by XREAL_1:72;
        then
A27:    -1 <= p2`1/|.p2.| by A5,A25,XCMPLX_1:197;
A28:    now
          per cases;
          case
            q2`2=0;
            then p2=q2 by A24,JGRAPH_4:49;
            hence p2`1/|.p2.|>-1 by A6,A22;
          end;
          case
            q2`2<>0;
            then
A29:        p2`2>0 by A1,A3,A24,Th18;
            now
              assume -1= p2`1/|.p2.|;
              then (-1)*|.p2.|=p2`1 by A5,A25,XCMPLX_1:87;
              then (|.p2.|)^2=(p2`1)^2;
              hence contradiction by A26,A29,XCMPLX_1:6;
            end;
            hence p2`1/|.p2.|>-1 by A27,XXREAL_0:1;
          end;
        end;
        p1=q1 by A19,A23,JGRAPH_4:49;
        hence thesis by A22,A28;
      end;
    end;
  end;
  hence thesis;
end;
