reserve i, i1, i2, j, j1, j2, k, m, n, t for Nat,
  D for non empty Subset of TOP-REAL 2,
  E for compact non vertical non horizontal Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p, q, x for Point of TOP-REAL 2,
  r, s for Real;

theorem Th21:
  for f being non constant standard special_circular_sequence st f
  is_sequence_on G & 1 <= t & t <= width G holds G*(1,t)`1 <= W-bound L~f
proof
  let f be non constant standard special_circular_sequence;
  W-min L~f in rng f by SPRECT_2:43;
  then consider x being object such that
A1: x in dom f and
A2: f.x = W-min L~f by FUNCT_1:def 3;
  reconsider x as Nat by A1;
  assume f is_sequence_on G;
  then consider i,j such that
A3: [i,j] in Indices G and
A4: f/.x = G*(i,j) by A1,GOBOARD1:def 9;
A5: 1 <= i & i <= len G by A3,MATRIX_0:32;
  assume
A6: 1 <= t & t <= width G;
  1 <= j & j <= width G by A3,MATRIX_0:32;
  then W-bound L~f = (W-min L~f)`1 & G*(1,t)`1 <= G*(i,j)`1 by A6,A5,Th18,
EUCLID:52;
  hence thesis by A1,A2,A4,PARTFUN1:def 6;
end;
