reserve a, b, i, k, m, n for Nat,
  r for Real,
  D for non empty Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2;

theorem Th21:
  ex i being Nat st 1 <= i & i <= len Gauge(C,n) &
  N-min L~Cage(C,n) = Gauge(C,n)*(i,width Gauge(C,n))
proof
A1: len Gauge(C,n) = width Gauge(C,n) by JORDAN8:def 1;
  N-min L~Cage(C,n) in rng Cage(C,n) by SPRECT_2:39;
  then consider m be Nat such that
A2: m in dom Cage(C,n) and
A3: Cage(C,n).m = N-min L~Cage(C,n) by FINSEQ_2:10;
A4: Cage(C,n)/.m = N-min L~Cage(C,n) by A2,A3,PARTFUN1:def 6;
  Cage(C,n) is_sequence_on Gauge(C,n) by JORDAN9:def 1;
  then consider i,j be Nat such that
A5: [i,j] in Indices Gauge(C,n) and
A6: Cage(C,n)/.m = Gauge(C,n)*(i,j) by A2,GOBOARD1:def 9;
  take i;
  thus
A7: 1 <= i & i <= len Gauge(C,n) by A5,MATRIX_0:32;
A8: 1 <= j by A5,MATRIX_0:32;
A9: now
    assume j < width Gauge(C,n);
    then
    (N-min L~Cage(C,n))`2 < Gauge(C,n)*(i,width Gauge(C,n))`2 by A4,A6,A7,A8,
GOBOARD5:4;
    then N-bound L~Cage(C,n) < Gauge(C,n)*(i,width Gauge(C,n))`2 by EUCLID:52;
    hence contradiction by A7,A1,JORDAN1A:70;
  end;
  j <= width Gauge(C,n) by A5,MATRIX_0:32;
  hence thesis by A4,A6,A9,XXREAL_0:1;
end;
