reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th21:
  0 < n implies UMP L~Cage(C,n) = UMP Upper_Arc L~Cage(C,n)
proof
  set f = Cage(C,n);
  set w = (E-bound C + W-bound C) / 2;
A1: Upper_Arc L~f c= L~f by JORDAN6:61;
A2: W-bound C + E-bound C = W-bound L~f + E-bound L~f by JORDAN1G:33;
A3: E-bound L~f = E-bound Upper_Arc L~f by JORDAN21:18;
A4: W-bound L~f = W-bound Upper_Arc L~f by JORDAN21:17;
  assume
A5: 0 < n;
  then
A6: 0+1 <= n by NAT_1:13;
  then
A7: n-'1+1 = n by XREAL_1:235;
A8: now
A9: Center Gauge(C,1) <= len Gauge(C,1) by JORDAN1B:13;
A10: Center Gauge(C,n) <= len Gauge(C,n) by JORDAN1B:13;
A11: Upper_Arc L~f \/ Lower_Arc L~f = L~f by JORDAN6:def 9;
    assume
A12: not UMP L~f in Upper_Arc L~f;
    UMP L~f in L~f by JORDAN21:30;
    then
A13: UMP L~f in Lower_Arc L~f by A12,A11,XBOOLE_0:def 3;
A14: len Gauge(C,n) = width Gauge(C,n) by JORDAN8:def 1;
A15: 1 <= Center Gauge(C,n) by JORDAN1B:11;
    consider j being Nat such that
A16: 1 <= j and
A17: j <= len Gauge(C,n) and
A18: UMP L~f = Gauge(C,n)*(Center Gauge(C,n),j) by A5,Th19;
    set a = Gauge(C,1)*(Center Gauge(C,1),len Gauge(C,1)), b = Gauge(C,n)*(
    Center Gauge(C,n),j), L = LSeg(a,b);
    len Gauge(C,1) = width Gauge(C,1) by JORDAN8:def 1;
    then L meets Upper_Arc L~f by A7,A13,A16,A17,A18,A14,JORDAN19:5;
    then consider x being object such that
A19: x in L and
A20: x in Upper_Arc L~f by XBOOLE_0:3;
    reconsider x as Point of TOP-REAL 2 by A19;
A21: a in L by RLTOPSP1:68;
A22: 1 <= len Gauge(C,1) by Lm3;
    then
A23: a`1 = w by JORDAN1A:38;
    then
A24: b`1 = w by A5,A16,A17,A22,JORDAN1A:36;
    then L is vertical by A23,SPPOL_1:16;
    then
A25: x`1 = w by A19,A23,A21,SPPOL_1:def 3;
    then x in Vertical_Line w;
    then
A26: x in Upper_Arc L~f /\ Vertical_Line w by A20,XBOOLE_0:def 4;
    then
A27: (UMP Upper_Arc L~f)`2 >= x`2 by A2,A4,A3,JORDAN21:28;
    1 <= Center Gauge(C,1) by JORDAN1B:11;
    then
A28: Gauge(C,1)*(Center Gauge(C,1),len Gauge(C,1))`2 >= Gauge(C,n)*(Center
    Gauge(C,n),len Gauge(C,n))`2 by A6,A15,A10,A9,JORDAN1A:40;
    len Gauge(C,n) = width Gauge(C,n) by JORDAN8:def 1;
    then
    Gauge(C,n)*(Center Gauge(C,n),len Gauge(C,n))`2 >= Gauge(C,n)*(Center
    Gauge(C,n),j)`2 by A16,A17,A15,A10,SPRECT_3:12;
    then a`2 >= b`2 by A28,XXREAL_0:2;
    then
A29: x`2 >= b`2 by A19,TOPREAL1:4;
    (UMP L~f)`2 >= (UMP Upper_Arc L~f)`2 by A1,A2,A4,A3,A26,JORDAN21:13,43;
    then b`2 >= x`2 by A18,A27,XXREAL_0:2;
    then b`2 = x`2 by A29,XXREAL_0:1;
    hence contradiction by A12,A18,A20,A24,A25,TOPREAL3:6;
  end;
  proj2.:(L~f /\ Vertical_Line w) is bounded_above by A2,JORDAN21:13;
  hence thesis by A1,A2,A4,A3,A8,JORDAN21:21,45;
end;
