reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;

theorem Th12:
  for A being Subset of TOP-REAL n holds UBD A is
  a_union_of_components of (TOP-REAL n) | A`
proof
  let A be Subset of TOP-REAL n;
  {B where B is Subset of TOP-REAL n: B is_outside_component_of A} c= bool
  (the carrier of ((TOP-REAL n) | A`))
  proof
    let x be object;
    assume
    x in {B where B is Subset of TOP-REAL n: B is_outside_component_of A};
    then consider B being Subset of TOP-REAL n such that
A1: x=B and
A2: B is_outside_component_of A;
    ex C being Subset of ((TOP-REAL n) | (A`)) st C=B & C is a_component
    & C is not bounded Subset of Euclid n by A2,Th8;
    hence thesis by A1;
  end;
  then reconsider
  F0={B where B is Subset of TOP-REAL n: B is_outside_component_of
  A} as Subset-Family of the carrier of ((TOP-REAL n) | A`);
  reconsider F0 as Subset-Family of ((TOP-REAL n) | A`);
A3: for B0 being Subset of ((TOP-REAL n) | A`) st B0 in F0 holds B0
  is a_component
  proof
    let B0 be Subset of ((TOP-REAL n) | A`);
    assume B0 in F0;
    then consider B being Subset of TOP-REAL n such that
A4: B=B0 and
A5: B is_outside_component_of A;
    ex C being Subset of ((TOP-REAL n) | (A`)) st C=B & C is a_component
    & C is not bounded Subset of Euclid n by A5,Th8;
    hence thesis by A4;
  end;
  UBD A=union F0;
  hence thesis by A3,CONNSP_3:def 2;
end;
