
theorem
  for L being distributive Lattice,
      a, b being Element of L st a <> b holds
    ex P being Ideal of L st P is prime &
      (a in P & not b in P) or (not a in P & b in P)
  proof
    let L be distributive Lattice,
        a, b be Element of L;
    assume
AA: a <> b;
ZZ: (.a.> misses <.b.) or <.a.) misses (.b.>
    proof
      assume
A0:   (.a.> meets <.b.) &
      <.a.) meets (.b.>; then
      consider x being object such that
A1:   x in (.a.> & x in <.b.) by XBOOLE_0:3;
      consider y being object such that
A2:   y in (.b.> & y in <.a.) by A0,XBOOLE_0:3;
      reconsider x,y as Element of L by A1,A2;
A3:   x [= a by A1,FILTER_2:28;
      b [= x by A1,FILTER_0:15; then
A5:   b [= a by A3,LATTICES:7;
A4:   y [= b by A2,FILTER_2:28;
      a [= y by A2,FILTER_0:15; then
      a [= b by A4,LATTICES:7;
      hence thesis by AA,A5,LATTICES:8;
    end;
    set I = (.a.>, F = <.b.);
    set I1 = (.b.>, F1 = <.a.);
    per cases by ZZ;
    suppose I misses F; then
      consider P being Ideal of L such that
B1:   P is prime & I c= P & P misses F by Th15;
B2:   a in P by B1,FILTER_2:28;
      b in F; then
      not b in P by B1,XBOOLE_0:3;
      hence thesis by B1,B2;
    end;
    suppose I1 misses F1; then
      consider P being Ideal of L such that
B1:   P is prime & I1 c= P & P misses F1 by Th15;
B2:   b in P by B1,FILTER_2:28;
      a in F1; then
      not a in P by B1,XBOOLE_0:3;
      hence thesis by B2;
    end;
  end;
