reserve T for non empty TopSpace,
  X,Z for Subset of T;
reserve x,y for Element of OpenClosedSet(T);
reserve x,y,X for set;
reserve BL for non trivial B_Lattice,
  a,b,c,p,q for Element of BL,
  UF,F,F0,F1,F2 for Filter of BL;

theorem Th21:
  UFilter BL.(a "\/" b) = UFilter BL.a \/ UFilter BL.b
proof
A1: UFilter BL.(a "\/" b) c= UFilter BL.a \/ UFilter BL.b
  proof
    let x be object;
    set c = a "\/" b;
    assume x in UFilter BL.c;
    then consider F0 such that
A2: x=F0 and
A3: F0 is being_ultrafilter and
A4: c in F0 by Th17;
    a in F0 or b in F0 by A3,A4,Th19;
    then F0 in UFilter BL.(a) or F0 in UFilter BL.(b) by A3,Th17;
    hence thesis by A2,XBOOLE_0:def 3;
  end;
  UFilter BL.a \/ UFilter BL.b c= UFilter BL.(a "\/" b)
  proof
    let x be object;
    assume x in UFilter BL.a \/ UFilter BL.b;
    then x in UFilter BL.a or x in UFilter BL.b by XBOOLE_0:def 3;
    then ( ex F0 st x=F0 & F0 is being_ultrafilter & a in F0 ) or
    ex F0 st x=F0 & F0 is being_ultrafilter & b in F0 by Th17;
    then consider F0 such that
A5: x=F0 and
A6: F0 is being_ultrafilter and
A7: a in F0 or b in F0;
    a "\/" b in F0 by A6,A7,Th19;
    hence thesis by A5,A6,Th17;
  end;
  hence thesis by A1;
end;
