
theorem Th23:
for a,b be Real st a < b holds
 ex E be SetSequence of L-Field st
  (for n be Nat holds E.n = [. a, b-(b-a)/(n+1) .] & E.n c= [.a,b.[ &
    E.n is non empty closed_interval Subset of REAL) &
  E is non-descending & E is convergent & Union E = [. a,b .[
proof
    let a,b be Real;
    assume A1: a < b;

    deffunc F(Element of NAT) = [. a, b-(b-a)/($1+1) .];
    consider E be Function of NAT, bool REAL such that
A2:  for n be Element of NAT holds E.n = F(n) from FUNCT_2:sch 4;

    now let x be object;
     assume x in rng E; then
     consider n be object such that
A3:   n in dom E & E.n = x by FUNCT_1:def 3;

     reconsider n as Element of NAT by A3;
     E.n = [.a,b-(b-a)/(n+1).] by A2;
     hence x in L-Field by A3,MEASUR10:5,MEASUR12:75;
    end; then
    rng E c= L-Field; then
    reconsider E as SetSequence of L-Field by RELAT_1:def 19;
    take E;

A4: for n be Nat holds E.n = [.a,b-(b-a)/(n+1).]
    proof
     let n be Nat;
     n is Element of NAT by ORDINAL1:def 12;
     hence thesis by A2;
    end;

    thus for n be Nat holds
     E.n = [.a,b-(b-a)/(n+1).] & E.n c= [.a,b.[
     & E.n is non empty closed_interval Subset of REAL
    proof
     let n be Nat;
     thus E.n = [.a,b-(b-a)/(n+1).] by A4;
A5:  E.n = [.a, b-(b-a)/(n+1).] by A4;
A6:  b-(b-a)/(n+1) < b by A1,Th22;
     a <= b-(b-a)/(n+1) by A1,Th22;
     hence thesis by A5,A6,MEASURE5:def 3,XXREAL_1:30,43;
    end;
    thus E is non-descending & E is convergent & Union E = [.a,b.[
     by A1,A4,Lm3;
end;
