reserve X for non empty set,
  Y for set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  f,g for PartFunc of X,COMPLEX,
  r for Real,
  k for Real,
  n for Nat,
  E for Element of S;

theorem Th21:
  for f be with_the_same_dom Functional_Sequence of X,REAL, E be
  Element of S st dom(f.0) = E & (for n be Nat holds f.n
is E-measurable) & (for x be Element of X st x in E holds f#x is convergent)
  holds lim f is E-measurable
proof
  let f be with_the_same_dom Functional_Sequence of X,REAL, E be Element of S;
  assume
A1: dom (f.0) = E;
  then
A2: dom lim f = E by MESFUNC8:def 9;
  assume for n be Nat holds f.n is E-measurable;
  then
A3: lim_sup f is E-measurable by A1,Th18;
  assume
A4: for x be Element of X st x in E holds f#x is convergent;
A5: now
    let x be Element of X;
    assume
A6: x in dom lim f;
    then f#x is convergent by A2,A4;
    hence (lim f).x= (lim_sup f).x by A6,Th15;
  end;
  dom lim_sup f = E by A1,MESFUNC8:def 8;
  hence thesis by A2,A3,A5,PARTFUN1:5;
end;
