reserve A for QC-alphabet;
reserve k,n,m for Nat;
reserve P for QC-pred_symbol of A;
reserve F for Element of QC-WFF(A);
reserve Q for QC-pred_symbol of A;
reserve F, G for (Element of QC-WFF(A)), s for FinSequence;
reserve p for Element of QC-WFF(A);
reserve F for Element of QC-WFF(A);
reserve p for Element of QC-WFF(A);
reserve j,k for Nat;
reserve k for Nat;
reserve s,t,u,v for QC-symbol of A;

theorem Th21:
  s <= t & t <= u implies s <= u
proof
  set R = the Relation of A;
  R well_orders QC-symbols(A) \ NAT by Def32;
  then
A1: R is_transitive_in QC-symbols(A) \ NAT by WELLORD1:def 5;
  assume
A2: s <= t & t <= u;
  per cases;
  suppose
A3: s in NAT;
    then
A4: t in NAT by A2,Def33;
    then
A5: u in NAT by A2,Def33;
    consider m,n such that
A6:  s = m & t = n & m <= n by A2,A3,A4,Def33;
    consider k,j such that
A7:  t = k & u = j & k <= j by A2,A4,A5,Def33;
    m <= j by A6,A7,XXREAL_0:2;
    hence s <= u by A6,A7,Def33,A3,A5;
  end;
  suppose
A8: not s in NAT;
    per cases;
    suppose t in NAT;
      then u in NAT by A2,Def33;
      hence thesis by A8,Def33;
    end;
    suppose
A9:   not t in NAT;
      per cases;
      suppose u in NAT;
        hence thesis by A8,Def33;
      end;
      suppose
A10:    not u in NAT;
        then
A11:    s in QC-symbols(A) \ NAT & t in QC-symbols(A) \ NAT & u in
         QC-symbols(A) \ NAT by A8,A9,XBOOLE_0:def 5;
        [s,t] in R & [t,u] in R by A2,A8,A9,A10,Def33;
        then [s,u] in R by A1,A11,RELAT_2:def 8;
        hence thesis by A8,A10,Def33;
      end;
    end;
  end;
end;
