reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;
reserve F for random_variable of S1,S2;

theorem Th21:
  for D be finite-yielding non-empty ManySortedSet of NAT,
  P be Probability_sequence of Trivial-SigmaField_sequence(D),
  n be Nat holds
  ex Pn be Probability of Trivial-SigmaField ((Product_dom(D)).n)
  st Pn = Product-Probability(P,D).n
  & Product-Probability(P,D).(n+1)
  = Product-Probability ( (Product_dom(D)).n,D.(n+1),Pn,P.(n+1))
  proof
    let D be finite-yielding non-empty ManySortedSet of NAT,
        P be Probability_sequence of Trivial-SigmaField_sequence(D),
        n be Nat;
    reconsider Pn = Product-Probability(P,D).n as
    Probability of Trivial-SigmaField ((Product_dom(D)).n) by Th20;
    take Pn;
    thus Pn = Product-Probability(P,D).n;
    thus Product-Probability(P,D).(n+1) = Product-Probability
    ( (Product_dom(D)).n,D.(n+1),
    modetrans(Product-Probability(P,D).n,
    Trivial-SigmaField ((Product_dom(D)).n)), P.(n+1)) by Def13
    .= Product-Probability ( (Product_dom(D)).n,D.(n+1),Pn,P.(n+1))
    by Def11;
  end;
