reserve x,y,X for set,
        r for Real,
        n,k for Nat;
reserve RLS for non empty RLSStruct,
        Kr,K1r,K2r for SimplicialComplexStr of RLS,
        V for RealLinearSpace,
        Kv for non void SimplicialComplex of V;

theorem Th21:
  |.Kv.| c= [#]Kv & degree Kv <= 0 implies the TopStruct of Kv = BCS Kv
 proof
  reconsider o=1 as ExtReal;
  assume that
   A1: |.Kv.|c=[#]Kv and
   A2: degree Kv<=0;
  set B=center_of_mass V,BC=BCS Kv;
  A3: BC=subdivision(center_of_mass V,Kv) by A1,Def5;
  then A4: [#]BC=[#]Kv by SIMPLEX0:def 20;
  A5: dom B=(bool the carrier of V)\{{}} by FUNCT_2:def 1;
  A6: 0+o=0+1 & degree Kv+o<=0+o by A2,XXREAL_3:35,def 2;
  A7: the topology of BC c=the topology of Kv
  proof
   let x be object;
   assume x in the topology of BC;
   then reconsider X=x as Simplex of BC by PRE_TOPC:def 2;
   reconsider X1=X as Subset of Kv by A4;
   consider S be c=-linear finite simplex-like Subset-Family of Kv such that
    A8: X=B.:S by A3,SIMPLEX0:def 20;
   A9: B.:S=B.:(S/\dom B) by RELAT_1:112;
   per cases;
   suppose X is empty;
    then X1 is simplex-like;
    hence thesis;
   end;
   suppose A10: X is non empty;
    then S is non empty by A8;
    then union S in S by SIMPLEX0:9;
    then reconsider U=union S as Simplex of Kv by TOPS_2:def 1;
    A11: U is non empty
    proof
     assume A12: U is empty;
     S/\dom B is empty
     proof
      assume S/\dom B is non empty;
      then consider y being object such that
       A13: y in S/\dom B;
      reconsider y as set by TARSKI:1;
      y in S by A13,XBOOLE_0:def 4;
      then A14: y c=U by ZFMISC_1:74;
      y<>{} by A13,ZFMISC_1:56;
      hence contradiction by A12,A14;
     end;
     hence contradiction by A8,A9,A10;
    end;
    then A15: @U in dom B by A5,ZFMISC_1:56;
    card U<=degree Kv+1 by SIMPLEX0:24;
    then A16: card U<=1 by A6,XXREAL_0:2;
    card U>=1 by A11,NAT_1:14;
    then A17: card U=1 by A16,XXREAL_0:1;
    then consider u be object such that
     A18: {u}=@U by CARD_2:42;
    u in {u} by TARSKI:def 1;
    then reconsider u as Element of V by A18;
    A19: S/\dom B c={U}
    proof
     let y be object;
    reconsider yy=y as set by TARSKI:1;
     assume A20: y in S/\dom B;
     then y in S by XBOOLE_0:def 4;
     then A21: yy c=U by ZFMISC_1:74;
     y<>{} by A20,ZFMISC_1:56;
     then y=U by A18,A21,ZFMISC_1:33;
     hence thesis by TARSKI:def 1;
    end;
    S/\dom B is non empty by A8,A9,A10;
    then S/\dom B={U} by A19,ZFMISC_1:33;
    then X=Im(B,U) by A8,A9,RELAT_1:def 16
     .={B.U} by A15,FUNCT_1:59
     .={1/1*Sum{u}} by A17,A18,RLAFFIN2:def 2
     .={Sum{u}} by RLVECT_1:def 8
     .=U by A18,RLVECT_2:9;
    hence thesis by PRE_TOPC:def 2;
   end;
  end;
  the topology of Kv c=the topology of BC
  proof
   let x be object;
   assume x in the topology of Kv;
   then reconsider X=x as Simplex of Kv by PRE_TOPC:def 2;
   reconsider X1=X as Subset of BC by A4;
   per cases;
   suppose X is empty;
    then X1 is simplex-like;
    hence thesis;
   end;
   suppose A22: X is non empty;
    for Y be Subset of Kv st Y in {X} holds Y is simplex-like by TARSKI:def 1;
    then reconsider XX={X} as finite simplex-like Subset-Family of Kv by
TOPS_2:def 1;
    now let x,y;
     assume that
      A23: x in XX and
      A24: y in XX;
     x=X by A23,TARSKI:def 1;
     hence x,y are_c=-comparable by A24,TARSKI:def 1;
    end;
    then A25: XX is c=-linear;
    card X<=degree Kv+1 by SIMPLEX0:24;
    then A26: card X<=1 by A6,XXREAL_0:2;
    card X>=1 by A22,NAT_1:14;
    then A27: card X=1 by A26,XXREAL_0:1;
    then consider u be object such that
     A28: @X={u} by CARD_2:42;
    A29: @X in dom B by A5,A22,ZFMISC_1:56;
    u in {u} by TARSKI:def 1;
    then reconsider u as Element of V by A28;
    B.:XX=Im(B,X) by RELAT_1:def 16
     .={B.X} by A29,FUNCT_1:59
     .={1/1*Sum{u}} by A27,A28,RLAFFIN2:def 2
     .={Sum{u}} by RLVECT_1:def 8
     .=X1 by A28,RLVECT_2:9;
    then X1 is simplex-like by A3,A25,SIMPLEX0:def 20;
    hence thesis;
   end;
  end;
  hence thesis by A3,A4,A7,XBOOLE_0:def 10;
 end;
