
theorem Th19: :: 4.61 i) Lexicographical order is admissible
  for n being Ordinal holds LexOrder n is admissible
proof
  let n be Ordinal;
  now
    let a,b be object such that
A1: a in Bags n and
A2: b in Bags n;
    reconsider a9=a, b9=b as bag of n by A1,A2;
    a9 <=' b9 or b9 <=' a9 by PRE_POLY:45;
    hence [a,b] in BagOrder n or [b,a] in BagOrder n by PRE_POLY:def 14;
  end;
  hence LexOrder n is_strongly_connected_in Bags n;
  now
    let a be bag of n;
    EmptyBag n <=' a by PRE_POLY:60;
    hence [EmptyBag n, a] in BagOrder n by PRE_POLY:def 14;
  end;
  hence for a being bag of n holds [EmptyBag n, a] in LexOrder n;
  now
    let a,b,c be bag of n;
    assume [a,b] in BagOrder n;
    then
A3: a <=' b by PRE_POLY:def 14;
    now per cases by A3,PRE_POLY:def 10;
      suppose a < b;
        then consider k being Ordinal such that
A4:     a.k < b.k and
A5:     for l being Ordinal st l in k holds a.l=b.l by PRE_POLY:def 9;
        now
          take k;
A6:       (a+c).k = a.k+c.k by PRE_POLY:def 5;
          (b+c).k = (b.k+c.k) by PRE_POLY:def 5;
          hence (a+c).k < (b+c).k by A4,A6,XREAL_1:6;
          let l be Ordinal such that
A7:       l in k;
A8:       (a+c).l = a.l+c.l by PRE_POLY:def 5;
          (b+c).l = b.l+c.l by PRE_POLY:def 5;
          hence (a+c).l = (b+c).l by A5,A7,A8;
        end;
        then a+c < b+c by PRE_POLY:def 9;
        hence a+c <=' b+c by PRE_POLY:def 10;
      end;
      suppose a = b;
        hence a+c <=' b+c;
      end;
    end;
    hence [a+c, b+c] in BagOrder n by PRE_POLY:def 14;
  end;
  hence thesis;
end;
