reserve Y for non empty set;
reserve B for Subset of Y;

theorem Th21:
  for d being constant Function of Y,BOOLEAN holds B_INF(d)
  = d & B_SUP(d) = d
proof
  let d be constant Function of Y,BOOLEAN;
A1: now
    assume
A2: (for x being Element of Y holds d.x=TRUE ) or for x being Element
    of Y holds d.x=FALSE;
    now
      per cases by A2;
      case
A3:     (for x being Element of Y holds d.x=TRUE) & not (for x being
        Element of Y holds d.x=FALSE);
        then d = I_el(Y) by Def11;
        hence thesis by A3,Def13,Def14;
      end;
      case
A4:     (for x being Element of Y holds d.x=FALSE) & not (for x being
        Element of Y holds d.x=TRUE);
        then d = O_el(Y) by Def10;
        hence thesis by A4,Def13,Def14;
      end;
      case
A5:     (for x being Element of Y holds d.x=TRUE) & for x being
        Element of Y holds d.x=FALSE;
        let x be Element of Y;
        d.x=TRUE by A5;
        hence thesis by A5;
      end;
    end;
    hence thesis;
  end;
  now
    assume that
A6: not( for x being Element of Y holds d.x=TRUE ) and
A7: not(for x being Element of Y holds d.x=FALSE);
    now
      per cases by Th20;
      case
        d=O_el(Y);
        hence thesis by A7,Def10;
      end;
      case
        d=I_el(Y);
        hence thesis by A6,Def11;
      end;
    end;
    hence thesis;
  end;
  hence thesis by A1;
end;
