
theorem Th22:
  for X be compact non empty TopSpace
  for seq be sequence of R_Normed_Algebra_of_ContinuousFunctions(X) st
    seq is Cauchy_sequence_by_Norm holds seq is convergent
proof
  let X be compact non empty TopSpace;
  let vseq be sequence of R_Normed_Algebra_of_ContinuousFunctions(X);
  assume
A1: vseq is Cauchy_sequence_by_Norm;
A2:for x being object st x in ContinuousFunctions(X) holds
     x in BoundedFunctions the carrier of X by Lm1;
  then
  ContinuousFunctions(X) c= BoundedFunctions the carrier of X;
  then rng vseq c= BoundedFunctions the carrier of X;
  then reconsider vseq1=vseq as sequence of
    R_Normed_Algebra_of_BoundedFunctions the carrier of X by FUNCT_2:6;
  now let e be Real such that
A3:   e >0;
    consider k be Nat such that
A4:   for n,m be Nat st n >= k & m >= k holds
        ||. vseq.n - vseq.m .|| < e by A1,A3,RSSPACE3:8;
    take k;
     let n,m be Nat;
      assume n >= k & m >= k;
      then
      ||. vseq.n - vseq.m .|| < e by A4;
      hence ||. vseq1.n - vseq1.m .|| < e by Lm9,Lm3;
  end;
  then
A5:vseq1 is Cauchy_sequence_by_Norm by RSSPACE3:8;
  then
A6: vseq1 is convergent by C0SP1:35;
  reconsider Y = ContinuousFunctions(X) as Subset of
     R_Normed_Algebra_of_BoundedFunctions the carrier of X by A2,TARSKI:def 3;
A7:rng vseq c= ContinuousFunctions(X);
  Y is closed by Th21;
  then
  reconsider tv=lim vseq1 as Point of
     R_Normed_Algebra_of_ContinuousFunctions(X) by A7,A5,Th20;
  for e be Real
    st e > 0 ex k be Nat st for n be Nat st
     n >= k holds ||.vseq.n - tv.|| < e
  proof
    let e be Real;
    assume e > 0;
    then
    consider k be Nat such that
A8:   for n be Nat st n >= k holds
        ||.vseq1.n - lim vseq1.|| < e by A6,NORMSP_1:def 7;
    take k;
    now
    let  n be Nat;
      assume n >= k;
      then
      ||.vseq1.n-lim vseq1.|| < e by A8;
      hence ||.vseq.n-tv.|| < e by Lm9,Lm3;
    end;
    hence for n be Nat st n >= k holds ||.vseq.n - tv.|| < e;
  end;
  hence thesis by NORMSP_1:def 6;
end;
