reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th22:
  for T being non empty TopSpace holds T is countably_compact iff
  for S be non-empty closed SetSequence of T st S is non-ascending holds meet S
  <> {}
proof
  let T being non empty TopSpace;
  thus T is countably_compact implies for S be non-empty closed SetSequence of
  T st S is non-ascending holds meet S <> {}
  proof
    assume
A1: T is countably_compact;
    let S be non-empty closed SetSequence of T such that
A2: S is non-ascending;
    reconsider rngS=rng S as Subset-Family of T;
    dom S=NAT by FUNCT_2:def 1;
    then
A3: rngS is countable by CARD_3:93;
    now
      let D be Subset of T;
      assume D in rngS;
      then ex x being object st x in dom S & S.x=D by FUNCT_1:def 3;
      hence D is closed by Def6;
    end;
    then
A4: rngS is closed;
    rngS is centered by A2,Th11;
    then meet rngS<>{} by A1,A3,A4,Th21;
    then consider x being object such that
A5: x in meet rngS by XBOOLE_0:def 1;
    now
      let n be Nat;
A6:    n in NAT by ORDINAL1:def 12;
      dom S=NAT by FUNCT_2:def 1;
      then S.n in rngS by FUNCT_1:def 3,A6;
      hence x in S.n by A5,SETFAM_1:def 1;
    end;
    hence thesis by KURATO_0:3;
  end;
  assume
A7: for S be non-empty closed SetSequence of T st S is non-ascending
  holds meet S <> {};
  now
    let F be Subset-Family of T such that
A8: F is centered and
A9: F is closed and
A10: F is countable;
A11: card F c= omega by A10,CARD_3:def 14;
    now
      per cases by A11,CARD_1:3;
      suppose
        card F = omega;
        then NAT,F are_equipotent by CARD_1:5,47;
        then consider s be Function such that
        s is one-to-one and
A12:    dom s = NAT and
A13:    rng s = F by WELLORD2:def 4;
        reconsider s as SetSequence of T by A12,A13,FUNCT_2:2;
        consider R be SetSequence of T such that
A14:    R is non-ascending and
A15:    F is centered implies R is non-empty and
        F is open implies R is open and
A16:    F is closed implies R is closed and
A17:    for i holds R.i=meet{s.j where j is Element of NAT:j<=i}by A13,Th13;
        meet R<>{} by A7,A8,A9,A14,A15,A16;
        then consider x being object such that
A18:    x in meet R by XBOOLE_0:def 1;
A19:    now
          let y;
          assume y in F;
          then consider z be object such that
A20:      z in dom s and
A21:      s.z=y by A13,FUNCT_1:def 3;
          reconsider z as Element of NAT by A20;
A22:      s.z in {s.j where j is Element of NAT:j<=z};
A23:      x in R.z by A18,KURATO_0:3;
          R.z=meet {s.j where j is Element of NAT:j<=z} by A17;
          then R.z c= s.z by A22,SETFAM_1:3;
          hence x in y by A21,A23;
        end;
        F is non empty by A12,A13,RELAT_1:42;
        hence meet F is non empty by A19,SETFAM_1:def 1;
      end;
      suppose
A24:    card F in omega;
        F is finite by A24;
        hence meet F is non empty by A8,FINSET_1:def 3;
      end;
    end;
    hence meet F<>{};
  end;
  hence thesis by Th21;
end;
