
theorem Th22:
  for X be non empty set, Y be ComplexNormSpace, f,g being Point
of C_NormSpace_of_BoundedFunctions(X,Y), c be Complex holds ( ||.f.|| = 0 iff f
= 0.C_NormSpace_of_BoundedFunctions(X,Y) ) & ||.c*f.|| = |.c.| * ||.f.|| & ||.f
  +g.|| <= ||.f.|| + ||.g.||
proof
  let X be non empty set;
  let Y be ComplexNormSpace;
  let f, g being Point of C_NormSpace_of_BoundedFunctions(X,Y);
  let c be Complex;
A1: now
    assume
A2: f = 0.C_NormSpace_of_BoundedFunctions(X,Y);
    thus ||.f.|| = 0
    proof
      reconsider g=f as bounded Function of X,the carrier of Y by Def5;
      set z = X --> 0.Y;
      reconsider z as Function of X, the carrier of Y;
      consider r0 be object such that
A3:   r0 in PreNorms(g) by XBOOLE_0:def 1;
      reconsider r0 as Real by A3;
A4:   (for s be Real st s in PreNorms(g) holds s <= 0)
implies upper_bound
      PreNorms(g) <= 0 by SEQ_4:45;
A5:   PreNorms(g) is non empty bounded_above by Th12;
A6:   z=g by A2,Th16;
A7:   now
        let r be Real;
        assume r in PreNorms(g);
        then consider t be Element of X such that
A8:     r=||.g.t.||;
        ||.g.t.|| = ||.0.Y.|| by A6,FUNCOP_1:7
          .= 0;
        hence 0 <= r & r <=0 by A8;
      end;
      then 0<=r0 by A3;
      then upper_bound PreNorms(g) = 0 by A7,A5,A3,A4,SEQ_4:def 1;
      then ComplexBoundedFunctionsNorm(X,Y).f =0 by Th15;
      hence thesis;
    end;
  end;
A9: ||.f+g.|| <= ||.f.|| + ||.g.||
  proof
    reconsider f1=f, g1=g, h1=f+g as bounded Function of X,the carrier of Y by
Def5;
A10: (for s be Real st s in PreNorms(h1) holds s <= ||.f.|| + ||.g
    .||) implies upper_bound PreNorms(h1) <= ||.f.|| + ||.g.|| by SEQ_4:45;
A11: now
      let t be Element of X;
      ||.f1.t.||<= ||.f.|| & ||.g1.t.||<= ||.g.|| by Th17;
      then
A12:  ||.f1.t.||+||.g1.t.|| <= ||.f.|| + ||.g.|| by XREAL_1:7;
      ||.h1.t.||= ||.f1.t+g1.t.|| & ||.f1.t+g1.t.|| <=||.f1.t.||+||.g1.t
      .|| by Th20,CLVECT_1:def 13;
      hence ||.h1.t.|| <= ||.f.|| + ||.g.|| by A12,XXREAL_0:2;
    end;
A13: now
      let r be Real;
      assume r in PreNorms(h1);
      then ex t be Element of X st r=||.h1.t.||;
      hence r <= ||.f.|| + ||.g.|| by A11;
    end;
    ComplexBoundedFunctionsNorm(X,Y).(f+g) = upper_bound PreNorms(h1) by Th15;
    hence thesis by A13,A10;
  end;
A14: ||.c*f.|| = |.c.| * ||.f.||
  proof
    reconsider f1=f, h1=c*f as bounded Function of X, the carrier of Y by Def5;
A15: (for s be Real st s in PreNorms(h1) holds s <= |.c.|*||.f.|| )
    implies upper_bound PreNorms(h1) <= |.c.|*||.f.|| by SEQ_4:45;
A16: now
      let t be Element of X;
A17:  0<= |.c.| by COMPLEX1:46;
      ||.h1.t.||= ||.c*f1.t.|| & ||.c*f1.t.|| =|.c.|*||.f1.t.|| by Th21,
CLVECT_1:def 13;
      hence ||.h1.t.|| <= |.c.|*||.f.|| by A17,Th17,XREAL_1:64;
    end;
A18: now
      let r be Real;
      assume r in PreNorms(h1);
      then ex t be Element of X st r=||.h1.t.||;
      hence r <= |.c.|*||.f.|| by A16;
    end;
A19: now
      per cases;
      case
A20:    c <> 0c;
A21:    now
          let t be Element of X;
A22:      |.c".| = |.1r/c.| by COMPLEX1:def 4,XCMPLX_1:215
            .= 1/|.c.| by COMPLEX1:48,67
            .= 1*(|.c.|)" by XCMPLX_0:def 9
            .= |.c.|";
          h1.t=c*f1.t by Th21;
          then
A23:      c"*h1.t =( c"* c)*f1.t by CLVECT_1:def 4
            .=1r*f1.t by A20,COMPLEX1:def 4,XCMPLX_0:def 7
            .=f1.t by CLVECT_1:def 5;
          ||.c"*h1.t.|| =|.c".|*||.h1.t.|| & 0<= |.c".| by CLVECT_1:def 13
,COMPLEX1:46;
          hence ||.f1.t.|| <= |.c.|"*||.c*f.|| by A23,A22,Th17,XREAL_1:64;
        end;
A24:    now
          let r be Real;
          assume r in PreNorms(f1);
          then ex t be Element of X st r=||.f1.t.||;
          hence r <= |.c.|"*||.c*f.|| by A21;
        end;
A25:    ( for s be Real st s in PreNorms(f1) holds s <= |.c.|"*||.
        c*f.|| ) implies upper_bound PreNorms(f1) <= |.c.|"*||.c*f.||
         by SEQ_4:45;
A26:    0 <= |.c.| by COMPLEX1:46;
        ComplexBoundedFunctionsNorm(X,Y).(f) = upper_bound PreNorms(f1)
         by Th15;
        then ||.f.|| <=|.c.|"*||.c*f.|| by A24,A25;
        then |.c.|*||.f.|| <= |.c.|*(|.c.|"*||.c*f.||) by A26,XREAL_1:64;
        then
A27:    |.c.|*||.f.|| <=(|.c.|*|.c.|")*||.c*f.||;
        |.c.| <>0 by A20,COMPLEX1:47;
        then |.c.|*||.f.|| <=1*||.c*f.|| by A27,XCMPLX_0:def 7;
        hence |.c.|* ||.f.|| <=||.c*f.||;
      end;
      case
A28:    c = 0c;
        reconsider fz=f as VECTOR of C_VectorSpace_of_BoundedFunctions(X,Y);
        c*f =Mult_(ComplexBoundedFunctions(X,Y), ComplexVectSpace(X,Y)).[
        c,f] by CLVECT_1:def 1
          .=c*fz by CLVECT_1:def 1
          .=0.C_VectorSpace_of_BoundedFunctions(X,Y) by A28,CLVECT_1:1
          .=0.C_NormSpace_of_BoundedFunctions(X,Y);
        hence thesis by A28,Th19,COMPLEX1:44;
      end;
    end;
    ComplexBoundedFunctionsNorm(X,Y).(c*f) = upper_bound PreNorms(h1) by Th15;
    then ||.c*f.|| <= |.c.|*||.f.|| by A18,A15;
    hence thesis by A19,XXREAL_0:1;
  end;
  now
    reconsider g=f as bounded Function of X,the carrier of Y by Def5;
    set z = X --> 0.Y;
    reconsider z as Function of X, the carrier of Y;
    assume
A29: ||.f.|| = 0;
    now
      let t be Element of X;
      ||.g.t.|| <= ||.f.|| by Th17;
      then ||.g.t.|| = 0 by A29,CLVECT_1:105;
      hence g.t =0.Y by NORMSP_0:def 5
        .=z.t by FUNCOP_1:7;
    end;
    then g=z by FUNCT_2:63;
    hence f=0.C_NormSpace_of_BoundedFunctions(X,Y) by Th16;
  end;
  hence thesis by A1,A14,A9;
end;
