reserve x,y,z for object,X,Y for set;
reserve N for e_net;

theorem
  (e_prox(N)) * (e_prox(N)) = e_prox(N) &
  (e_prox(N) \ id(e_shore(N))) * e_prox(N) = {} &
  (e_prox(N) \/ (e_prox(N))~) \/ id(e_shore(N)) = e_flow(N) \/ (e_flow(N))~
proof
  set R = the entrance of N;
  set S = the escape of N;
  set T = id(the carrier of N);
A1: (e_prox(N) \/ (e_prox(N))~) \/ id(e_shore(N)) = ((R~ \/ S~) \/ (S \/ R))
  \/ T by RELAT_1:23
    .= (((R~ \/ S~) \/ S) \/ R) \/ T by XBOOLE_1:4
    .= ((R~ \/ (S~ \/ S)) \/ R) \/ T by XBOOLE_1:4
    .= (R~ \/ ((S \/ S~) \/ R)) \/ T by XBOOLE_1:4
    .= (R~ \/ (S \/ (S~ \/ R))) \/ T by XBOOLE_1:4
    .= ((R~ \/ S) \/ (S~ \/ R)) \/ T by XBOOLE_1:4
    .= e_flow(N) \/ ((S~ \/ (R~)~) \/ T) by XBOOLE_1:5
    .= e_flow(N) \/ ((R~ \/ S)~ \/ T) by RELAT_1:23
    .= e_flow(N) \/ ((R~ \/ S)~ \/ T~)
    .= e_flow(N) \/ (e_flow(N))~ by RELAT_1:23;
A2: (e_prox(N) \ T) * e_prox(N) = ((R~ \/ S~) \ T) * ((R \/ S)~) by RELAT_1:23
    .= ((R~ \ T) \/ (S~ \ T)) * ((R \/ S)~) by XBOOLE_1:42
    .= ((R~ \ T) \/ (S~ \ T)) * (R~ \/ S~) by RELAT_1:23
    .= (((R~ \ T) \/ (S~ \ T)) * R~) \/ (((R~ \ T) \/ (S~ \ T)) * S~) by
RELAT_1:32
    .= (((R~ \ T) * R~) \/ ((S~ \ T) * R~)) \/ (((R~ \ T) \/ (S~ \ T)) * S~)
  by SYSREL:6
    .= (((R~ \ T) * R~) \/ ((S~ \ T) * R~)) \/ (((R~ \ T) * S~) \/ ((S~ \ T)
  * S~)) by SYSREL:6
    .= (((R~ \ T~) * R~) \/ ((S~ \ T) * R~)) \/ (((R~ \ T) * S~) \/ ((S~ \ T
  ) * S~))
    .= (((R~ \ T~) * R~) \/ ((S~ \ T~) * R~)) \/ (((R~ \ T) * S~) \/ ((S~ \
  T) * S~))
    .= (((R~ \ T~) * R~) \/ ((S~ \ T~) * R~)) \/ (((R~ \ T~) * S~) \/ ((S~ \
  T) * S~))
    .= (((R~ \ T~) * R~) \/ ((S~ \ T~) * R~)) \/ (((R~ \ T~) * S~) \/ ((S~ \
  T~) * S~))
    .= (((R \ T)~ * R~) \/ ((S~ \ T~) * R~)) \/ (((R~ \ T~) * S~) \/ ((S~ \
  T~) * S~)) by RELAT_1:24
    .= (((R \ T)~ * R~) \/ ((S \ T)~ * R~)) \/ (((R~ \ T~) * S~) \/ ((S~ \ T
  ~) * S~)) by RELAT_1:24
    .= (((R \ T)~ * R~) \/ ((S \ T)~ * R~)) \/ (((R \ T)~ * S~) \/ ((S~ \ T~
  ) * S~)) by RELAT_1:24
    .= (((R \ T)~ * R~) \/ ((S \ T)~ * R~)) \/ (((R \ T)~ * S~) \/ ((S \ T)~
  * S~)) by RELAT_1:24
    .= ((R * (R \ T))~ \/ ((S \ T)~ * R~)) \/ (((R \ T)~ * S~) \/ ((S \ T)~
  * S~)) by RELAT_1:35
    .= ((R * (R \ T))~ \/ (R * (S \ T))~) \/ (((R \ T)~ * S~) \/ ((S \ T)~ *
  S~)) by RELAT_1:35
    .= ((R * (R \ T))~ \/ (R * (S \ T))~) \/ ((S *(R \ T))~ \/ ((S \ T)~ * S
  ~)) by RELAT_1:35
    .= ((R * (R \ T))~ \/ (R * (S \ T))~) \/ ((S * (R \ T))~ \/ (S * (S \ T)
  )~) by RELAT_1:35
    .= (({}~) \/ (R * (S \ T))~) \/ ((S * (R \ T))~ \/ (S * (S \ T))~) by Def2
    .= (({}~) \/ (R * (S \ T))~) \/ ((S * (R \ T))~ \/ ({})~) by Def2
    .= ({}~ \/ {}~) \/ ((S * (R \ T))~ \/ {}~) by Th15
    .= {} by Th15;
  (e_prox(N)) * (e_prox(N)) = ((R \/ S) * (R \/ S))~ by RELAT_1:35
    .= (((R \/ S) * R) \/ ((R \/ S) * S))~ by RELAT_1:32
    .= (((R * R) \/ (S * R)) \/ ((R \/ S) * S))~ by SYSREL:6
    .= (((R * R) \/ (S * R)) \/ ((R * S) \/ (S * S)))~ by SYSREL:6
    .= ((R \/ (S * R)) \/ ((R * S) \/ (S * S) ) )~ by Def1
    .= ((R \/ S) \/ ((R * S) \/ (S * S)))~ by Def1
    .= ((R \/ S) \/ (R \/ (S * S)))~ by Def1
    .= ((R \/ S) \/ (R \/ S))~ by Def1
    .= e_prox(N);
  hence thesis by A2,A1;
end;
