
theorem Th22:
  for n being Nat st n >= 2 & n is even holds
    Fib (n+1) = [\ tau * Fib n + 1 /]
  proof
    let n be Nat;
    assume A1: n >= 2 & n is even;
    set t = tau;
    set tb = tau_bar;
A2: sqrt 5 > 0 by SQUARE_1:17,27;
A3: t * tb = (1 ^2 - (sqrt 5) ^2) / 4 by FIB_NUM:def 1,def 2
    .= (1-5)/4 by SQUARE_1:def 2
    .= -1;
    tb to_power n = (-tb) to_power n by A1,Th3; then
A4: tb to_power n > 0 by POWER:34;
A5: tb to_power 2 + 1 = tb ^2 + 1 by POWER:46
    .= (1 ^2 - 2 * 1 * sqrt 5 + (sqrt 5) ^2) / 4 + 1 by FIB_NUM:def 2
    .= (1 - 2 * sqrt 5 + 5) / 4 + 1 by SQUARE_1:def 2
    .= (5 - sqrt 5) / 2
    .= ((sqrt 5) ^2 - sqrt 5) / 2 by SQUARE_1:def 2
    .= -(sqrt 5) * tb by FIB_NUM:def 2;
    t * Fib n = t * ((t to_power n - tb to_power n) / sqrt 5) by FIB_NUM:7
    .= (t * (t to_power n - tb to_power n)) / sqrt 5 by XCMPLX_1:74
    .= (t * (t to_power n) - t * (tb to_power n)) / sqrt 5
    .= ((t to_power 1) * (t to_power n) - t * (tb to_power n)) / sqrt 5
    .= (t to_power (n+1) - t * (tb to_power ((n-1)+1))) / sqrt 5 by POWER:27
    .= (t to_power (n+1) - t * ((tb to_power (n-1)) * (tb to_power 1))) /sqrt 5
    by Th2
    .= (t to_power (n+1) - t * ((tb to_power (n-1)) * tb)) / sqrt 5
    .= (t to_power (n+1) - t * tb * (tb to_power (n-1))) / sqrt 5
    .= (t to_power (n+1) - (-1) * (tb to_power (n-1))+
    tb to_power (n-1) - tb to_power (n-1)) / sqrt 5 by A3
    .= (((t to_power (n+1) - tb to_power (n+1))) + (tb to_power (n-1) +
    tb to_power (n+1))) / sqrt 5
    .= ((t to_power (n+1) - tb to_power (n+1))) / sqrt 5 + (tb to_power (n-1) +
    tb to_power ((n-1)+2)) / sqrt 5 by XCMPLX_1:62
    .= Fib (n+1) + (tb to_power (n-1) +
    tb to_power ((n-1)+2)) / sqrt 5 by FIB_NUM:7
    .= Fib (n+1) + ((tb to_power (n-1)) * 1 +
    (tb to_power (n-1)) * (tb to_power 2)) / sqrt 5 by Th2
    .= Fib (n+1) + ((tb to_power (n-1)) * (1 + (tb to_power 2))) / sqrt 5
    .= Fib (n+1) + ((tb to_power (n-1)) * (-(sqrt 5) * tb)) / sqrt 5 by A5
    .= Fib (n+1) + ((-1) * (tb to_power (n-1)) * tb * (sqrt 5)) / sqrt 5
    .= Fib (n+1) + ((-1) * (tb to_power (n-1))*tb) by A2,XCMPLX_1:89
    .= Fib (n+1) - ((tb to_power (n-1)) * tb)
    .= Fib (n+1) - ((tb to_power (n-1)) * (tb to_power 1))
    .= Fib (n+1) - (tb to_power (n-1+1)) by Th2
    .= Fib (n+1) - (tb to_power n); then
A6:  Fib (n+1) = (t * Fib n + 1) - (1 - (tb to_power n));
    tb to_power n < 1 by Th8,A1,XXREAL_0:2; then
    - (tb to_power n) > - 1 by XREAL_1:24; then
    - (tb to_power n) + 1 > - 1 + 1 by XREAL_1:8; then
A7: Fib (n+1) < t * Fib n + 1 by A6,XREAL_1:44;
    t * Fib n + 1 < Fib (n+1) + 1
    proof
A8:   t * Fib n = t * ((t to_power n - tb to_power n) / sqrt 5) by FIB_NUM:7
      .= (t*(t to_power n - tb to_power n)) / sqrt 5 by XCMPLX_1:74
      .= (t*t to_power n - t * tb to_power n) / sqrt 5
      .= (t to_power 1 * t to_power n - t * tb to_power n) /sqrt 5
      .= (t to_power (n+1) - t * tb to_power n) / sqrt 5 by POWER:27
      .= t to_power (n+1)/sqrt 5 - (t * tb to_power n) /sqrt 5 by XCMPLX_1:120;
A9:   Fib (n+1) = (t to_power (n+1) - tb to_power (n+1)) / sqrt 5 by FIB_NUM:7
      .= t to_power (n+1) / sqrt 5 - tb to_power (n+1) /sqrt 5 by XCMPLX_1:120;
      (tb to_power n * t) > (tb to_power n * tb) by A4,XREAL_1:68; then
      (tb to_power n * t) > (tb to_power n * tb to_power 1); then
      (t * tb to_power n)/sqrt 5 > (tb to_power n * tb to_power 1) / sqrt 5
      by A2,XREAL_1:74; then
      (t * tb to_power n)/sqrt 5 > tb to_power (n+1)/sqrt 5 by Th2; then
      - (t * tb to_power n)/sqrt 5 < - tb to_power (n+1) /sqrt 5 by XREAL_1:24;
      then - (t * tb to_power n) / sqrt 5 + t to_power (n+1) / sqrt 5 <
      - tb to_power (n+1) / sqrt 5 + t to_power (n+1) / sqrt 5 by XREAL_1:8;
      hence thesis by A8,A9,XREAL_1:8;
    end; then
    t * Fib n + 1 - 1 < Fib (n+1) + 1 - 1 by XREAL_1:9;
    hence thesis by A7,INT_1:def 6;
  end;
