
theorem Th22:
  for T being non empty TopSpace st T is sequential holds (for A
  being Subset of T holds Cl_Seq(Cl_Seq(A)) = Cl_Seq(A)) implies T is Frechet
proof
  let T be non empty TopSpace;
  assume
A1: T is sequential;
  assume
A2: for A being Subset of T holds Cl_Seq(Cl_Seq(A)) = Cl_Seq(A);
  assume not T is Frechet;
  then consider A being Subset of T such that
A3: ex x being Point of T st x in Cl(A) & for S being sequence of T
  holds (rng S c= A implies not x in Lim S );
  for Sq being sequence of T st Sq is convergent & rng Sq c= Cl_Seq(A)
  holds Lim Sq c= Cl_Seq(A)
  proof
    let Sq be sequence of T;
    assume that
    Sq is convergent and
A4: rng Sq c= Cl_Seq(A);
    let y be object;
    assume
A5: y in Lim Sq;
    then reconsider y9=y as Point of T;
    y9 in Cl_Seq(Cl_Seq(A)) by A4,A5,Def1;
    hence thesis by A2;
  end;
  then
A6: Cl_Seq(A) is closed by A1;
  consider x being Point of T such that
A7: x in Cl(A) and
A8: for S being sequence of T holds (rng S c= A implies not x in Lim S ) by A3;
  A c= Cl_Seq(A) by Th18;
  then x in Cl_Seq(A) by A7,A6,PRE_TOPC:15;
  hence contradiction by A8,Def1;
end;
