reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th22:
  Int cell(G,len G,width G) = { |[r,s]| : G*(len G,1)`1 < r & G*(1
  ,width G)`2 < s }
proof
  cell(G,len G,width G) = v_strip(G,len G) /\ h_strip(G,width G) by
GOBOARD5:def 3;
  then
A1: Int cell(G,len G,width G) = Int v_strip(G,len G) /\ Int h_strip(G, width
  G) by TOPS_1:17;
A2: Int h_strip(G,width G) = { |[r,s]| : G*(1,width G)`2 < s } by Th16;
A3: Int v_strip(G,len G) = { |[r,s]| : G*(len G,1)`1 < r } by Th13;
  thus Int cell(G,len G,width G) c= { |[r,s]| : G*(len G,1)`1 < r & G*(1,width
  G)`2 < s }
  proof
    let x be object;
    assume
A4: x in Int cell(G,len G,width G);
    then x in Int v_strip(G,len G) by A1,XBOOLE_0:def 4;
    then consider r1,s1 such that
A5: x = |[r1,s1]| and
A6: G*(len G,1)`1 < r1 by A3;
    x in Int h_strip(G,width G) by A1,A4,XBOOLE_0:def 4;
    then consider r2,s2 such that
A7: x = |[r2,s2]| and
A8: G*(1,width G)`2 < s2 by A2;
    s1 = s2 by A5,A7,SPPOL_2:1;
    hence thesis by A5,A6,A8;
  end;
  let x be object;
  assume x in { |[r,s]| : G*(len G,1)`1 < r & G*(1,width G)`2 < s };
  then
A9: ex r,s st x = |[r,s]| & G*(len G,1)`1 < r & G*(1,width G)`2 < s;
  then
A10: x in Int h_strip(G,width G) by A2;
  x in Int v_strip(G,len G) by A3,A9;
  hence thesis by A1,A10,XBOOLE_0:def 4;
end;
