reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;
reserve sc for oriented simple Chain of G;
reserve x,y for set;

theorem
  p is OrientedPath of G implies p|Seg(n) is OrientedPath of G
proof
  assume
A1: p is OrientedPath of G;
  then reconsider p9=p|(Seg n) as oriented Chain of G by Th16;
  reconsider q=p|(Seg n) as FinSequence;
  now
    let n1,m1 be Nat;
    assume that
A2: 1<=n1 and
A3: n1 < m1 and
A4: m1<=len q;
    1<m1 by A2,A3,XXREAL_0:2;
    then m1 in dom q by A4,FINSEQ_3:25;
    then
A5: q.m1=p.m1 by FUNCT_1:47;
    n1 < len q by A3,A4,XXREAL_0:2;
    then n1 in dom q by A2,FINSEQ_3:25;
    then
A6: q.n1=p.n1 by FUNCT_1:47;
    dom q c= dom p by RELAT_1:60;
    then dom q c= Seg len p by FINSEQ_1:def 3;
    then Seg len q c= Seg len p by FINSEQ_1:def 3;
    then len q<=len p by FINSEQ_1:5;
    then m1<=len p by A4,XXREAL_0:2;
    hence q.n1 <> q.m1 by A1,A2,A3,A5,A6,GRAPH_1:def 16;
  end;
  then p9 is Path of G by GRAPH_1:def 16;
  hence thesis;
end;
