
theorem
  for R being non degenerated comRing holds R is Field iff for I being
  Ideal of R holds (I = {0.R} or I = the carrier of R)
proof
  let R be non degenerated comRing;
A1: now
    assume
A2: R is Field;
    thus for I being Ideal of R holds (I = {0.R} or I = the carrier of R)
    proof
      let I be Ideal of R;
      assume
A3:   I <> {0.R};
      reconsider R as Field by A2;
      ex a being Element of R st a in I & a <> 0.R
      proof
        assume
A4:     not(ex a being Element of R st a in I & a <> 0.R);
A5:     now
          let u be object;
          assume u in I;
          then reconsider u9 = u as Element of I;
          u9 = 0.R by A4;
          hence u in {0.R} by TARSKI:def 1;
        end;
        now
          let u be object;
          assume
A6:       u in {0.R};
          then reconsider u9 = u as Element of R;
          u9 = 0.R by A6,TARSKI:def 1;
          hence u in I by Th3;
        end;
        hence thesis by A3,A5,TARSKI:2;
      end;
      then consider a being Element of R such that
A7:   a in I and
A8:   a <> 0.R;
      ex b being Element of R st b*a = 1.R by A8,VECTSP_1:def 9;
      then 1.R in I by A7,Def3;
      then I is non proper by Th19;
      hence thesis by SUBSET_1:def 6;
    end;
  end;
  now
    assume
A9: for I being Ideal of R holds (I= {0.R} or I = the carrier of R );
    now
      let a be Element of R;
      reconsider a9 = a as Element of R;
      reconsider M = the set of all a9*r where r is Element of R  as
      Ideal of R by Lm1;
      a*1.R = a;
      then
A10:  a in M;
      assume a <> 0.R;
      then M <> {0.R} by A10,TARSKI:def 1;
      then M = the carrier of R by A9;
      then 1.R in M;
      then ex b being Element of R st a*b = 1.R;
      hence ex b being Element of R st b*a = 1.R;
    end;
    hence R is Field by VECTSP_1:def 9;
  end;
  hence thesis by A1;
end;
