reserve a,a1,b,b1,x,y for Real,
  F,G,H for FinSequence of REAL,
  i,j,k,n,m for Element of NAT,
  I for Subset of REAL,
  X for non empty set,
  x1,R,s for set;
reserve A for non empty closed_interval Subset of REAL;
reserve A, B for non empty closed_interval Subset of REAL;
reserve r for Real;
reserve D, D1, D2 for Division of A;
reserve f, g for Function of A,REAL;

theorem Th20:
  len F = len G & len F = len H & (for k st k in dom F holds H.k =
  F/.k - G/.k) implies Sum(H) = Sum(F) - Sum(G)
proof
  assume that
A1: len F = len G and
A2: len F = len H and
A3: for k st k in dom F holds H.k = F/.k - G/.k;
A4: F is Element of (len F)-tuples_on REAL by FINSEQ_2:92;
A5: G is Element of (len F)-tuples_on REAL by A1,FINSEQ_2:92;
  then
A6: F-G is Element of (len F)-tuples_on REAL by A4,FINSEQ_2:120;
  then
A7: len H = len (F-G) by A2,CARD_1:def 7;
  then
A8: dom H = Seg len (F-G) by FINSEQ_1:def 3;
A9: for k st k in dom F holds H.k = F.k - G.k
  proof
    let k;
    assume
A10: k in dom F;
    then k in Seg(len G) by A1,FINSEQ_1:def 3;
    then k in dom G by FINSEQ_1:def 3;
    then
A11: G/.k = G.k by PARTFUN1:def 6;
    F/.k = F.k by A10,PARTFUN1:def 6;
    hence thesis by A3,A10,A11;
  end;
  for k being Nat st k in dom H holds H.k = (F-G).k
  proof
    let k be Nat;
    assume
A12: k in dom H;
    then k in Seg(len F) by A6,A8,CARD_1:def 7;
    then k in dom F by FINSEQ_1:def 3;
    then
A13: H.k=F.k-G.k by A9;
    k in dom(F-G) by A8,A12,FINSEQ_1:def 3;
    hence thesis by A13,VALUED_1:13;
  end;
  then Sum H=Sum(F-G) by A7,FINSEQ_2:9
    .=Sum F-Sum G by A4,A5,RVSUM_1:90;
  hence thesis;
end;
