reserve n for Nat;

theorem Th22:
  for C be Simple_closed_curve for i1,i2,j,k be Nat st
  1 < i2 & i2 <= i1 & i1 < len Gauge(C,n) &
  1 <= j & j <= k & k <= width Gauge(C,n) &
  (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) /\ L~Upper_Seq(C,n) =
  {Gauge(C,n)*(i1,j)} & (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) /\ L~Lower_Seq(C,n) =
  {Gauge(C,n)*(i2,k)} holds (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) meets Upper_Arc C
proof
  let C be Simple_closed_curve;
  let i1,i2,j,k be Nat;
  set G = Gauge(C,n);
  set pio = LSeg(G*(i1,j),G*(i1,k));
  set poz = LSeg(G*(i1,k),G*(i2,k));
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  assume that
A1: 1 < i2 and
A2: i2 <= i1 and
A3: i1 < len G and
A4: 1 <= j and
A5: j <= k and
A6: k <= width G and
A7: (pio \/ poz) /\ L~US = {G*(i1,j)} and
A8: (pio \/ poz) /\ L~LS = {G*(i2,k)} and
A9: (pio \/ poz) misses Upper_Arc C;
  set UA = Upper_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gik = G*(i2,k);
  set Gij = G*(i1,j);
  set Gi1k = G*(i1,k);
A10: 1 < i1 by A1,A2,XXREAL_0:2;
A11: i2 < len G by A2,A3,XXREAL_0:2;
A12: L~<*Gij,Gi1k,Gik*> = poz \/ pio by TOPREAL3:16;
  Gik in {Gik} by TARSKI:def 1;
  then
A13: Gik in L~LS by A8,XBOOLE_0:def 4;
  Gij in {Gij} by TARSKI:def 1;
  then
A14: Gij in L~US by A7,XBOOLE_0:def 4;
A15: j <= width G by A5,A6,XXREAL_0:2;
A16: 1 <= k by A4,A5,XXREAL_0:2;
A17: [i1,j] in Indices G by A3,A4,A10,A15,MATRIX_0:30;
A18: [i2,k] in Indices G by A1,A6,A11,A16,MATRIX_0:30;
A19: [i1,k] in Indices G by A3,A6,A10,A16,MATRIX_0:30;
  set go = R_Cut(US,Gij);
  set co = L_Cut(LS,Gik);
A20: len G = width G by JORDAN8:def 1;
A21: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A22: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A23: Wmin`1 = Wbo
    .= G*(1,k)`1 by A6,A16,A20,JORDAN1A:73;
  len G >= 4 by JORDAN8:10;
  then
A24: len G >= 1 by XXREAL_0:2;
  then
A25: [1,k] in Indices G by A6,A16,MATRIX_0:30;
  then
A26: Gij <> US.1 by A1,A2,A17,A22,A23,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2
  by A14,JORDAN3:35;
A27: len LS >= 1+2 by JORDAN1E:15;
  then
A28: len LS >= 1 by XXREAL_0:2;
  then
A29: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A28,FINSEQ_3:25;
  then
A30: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
  Wmin`1 = Wbo
    .= G*(1,k)`1 by A6,A16,A20,JORDAN1A:73;
  then
A31: Gik <> LS.len LS by A1,A18,A25,A30,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2
  by A13,JORDAN3:34;
A32: [len G,k] in Indices G by A6,A16,A24,MATRIX_0:30;
A33: LS.1 = LS/.1 by A29,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo
    .= G*(len G,k)`1 by A6,A16,A20,JORDAN1A:71;
  then
A34: Gik <> LS.1 by A2,A3,A18,A32,A33,JORDAN1G:7;
A35: len go >= 1+1 by TOPREAL1:def 8;
A36: Gij in rng US by A3,A4,A10,A14,A15,JORDAN1G:4,JORDAN1J:40;
  then
A37: go is_sequence_on G by JORDAN1G:4,JORDAN1J:38;
A38: len co >= 1+1 by TOPREAL1:def 8;
A39: Gik in rng LS by A1,A6,A11,A13,A16,JORDAN1G:5,JORDAN1J:40;
  then
A40: co is_sequence_on G by JORDAN1G:5,JORDAN1J:39;
  reconsider go as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A35,A37,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A38,A40,JGRAPH_1:12,JORDAN8:5;
A41: len go > 1 by A35,NAT_1:13;
  then
A42: len go in dom go by FINSEQ_3:25;
  then
A43: go/.len go = go.len go by PARTFUN1:def 6
    .= Gij by A14,JORDAN3:24;
  len co >= 1 by A38,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A44: co/.1 = co.1 by PARTFUN1:def 6
    .= Gik by A13,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A42,FINSEQ_3:26;
A45: m+1 = len go;
  then
A46: len go-'1 = m by NAT_D:34;
A47: LSeg(go,m) c= L~go by TOPREAL3:19;
A48: L~go c= L~US by A14,JORDAN3:41;
  then LSeg(go,m) c= L~US by A47;
  then
A49: LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*> c= {Gij} by A7,A12,XBOOLE_1:26;
  m >= 1 by A35,XREAL_1:19;
  then
A50: LSeg(go,m) = LSeg(go/.m,Gij) by A43,A45,TOPREAL1:def 3;
  {Gij} c= LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*>
  proof
    let x be object;
    assume x in {Gij};
    then
A51: x = Gij by TARSKI:def 1;
A52: Gij in LSeg(go,m) by A50,RLTOPSP1:68;
    Gij in LSeg(Gij,Gi1k) by RLTOPSP1:68;
    then Gij in LSeg(Gij,Gi1k) \/ LSeg(Gi1k,Gik) by XBOOLE_0:def 3;
    then Gij in L~<*Gij,Gi1k,Gik*> by SPRECT_1:8;
    hence thesis by A51,A52,XBOOLE_0:def 4;
  end;
  then
A53: LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*> = {Gij} by A49;
A54: LSeg(co,1) c= L~co by TOPREAL3:19;
A55: L~co c= L~LS by A13,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A54;
  then
A56: LSeg(co,1) /\ L~<*Gij,Gi1k,Gik*> c= {Gik} by A8,A12,XBOOLE_1:26;
A57: LSeg(co,1) = LSeg(Gik,co/.(1+1)) by A38,A44,TOPREAL1:def 3;
  {Gik} c= LSeg(co,1) /\ L~<*Gij,Gi1k,Gik*>
  proof
    let x be object;
    assume x in {Gik};
    then
A58: x = Gik by TARSKI:def 1;
A59: Gik in LSeg(co,1) by A57,RLTOPSP1:68;
    Gik in LSeg(Gi1k,Gik) by RLTOPSP1:68;
    then Gik in LSeg(Gij,Gi1k) \/ LSeg(Gi1k,Gik) by XBOOLE_0:def 3;
    then Gik in L~<*Gij,Gi1k,Gik*> by SPRECT_1:8;
    hence thesis by A58,A59,XBOOLE_0:def 4;
  end;
  then
A60: L~<*Gij,Gi1k,Gik*> /\ LSeg(co,1) = {Gik} by A56;
A61: go/.1 = US/.1 by A14,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A62: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A13,JORDAN1J:35;
A63: rng go c= L~go by A35,SPPOL_2:18;
A64: rng co c= L~co by A38,SPPOL_2:18;
A65: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A66: x = go/.1 by TARSKI:def 1;
    then
A67: x in rng go by FINSEQ_6:42;
    x in rng co by A62,A66,FINSEQ_6:168;
    hence thesis by A63,A64,A67,XBOOLE_0:def 4;
  end;
A68: LS.1 = LS/.1 by A29,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A69: [len G,j] in Indices G by A4,A15,A24,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A70: x in L~go /\ L~co;
    then
A71: x in L~go by XBOOLE_0:def 4;
A72: x in L~co by A70,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A48,A55,A71,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then
A73: x = Wmin or x = Emax by TARSKI:def 2;
    now
      assume x = Emax;
      then
A74:  Emax = Gik by A13,A68,A72,JORDAN1E:7;
      G*(len G,j)`1 = Ebo by A4,A15,A20,JORDAN1A:71;
      then Emax`1 <> Ebo by A2,A3,A18,A69,A74,JORDAN1G:7;
      hence contradiction;
    end;
    hence thesis by A61,A73,TARSKI:def 1;
  end;
  then
A75: L~go /\ L~co = {go/.1} by A65;
  set W2 = go/.2;
A76: 2 in dom go by A35,FINSEQ_3:25;
A77: now
    assume Gik`1 = Wbo;
    then G*(1,k)`1 = G*(i2,k)`1 by A6,A16,A20,JORDAN1A:73;
    hence contradiction by A1,A18,A25,JORDAN1G:7;
  end;
  go = mid(US,1,Gij..US) by A36,JORDAN1G:49
    .= US|(Gij..US) by A36,FINSEQ_4:21,FINSEQ_6:116;
  then
A78: W2 = US/.2 by A76,FINSEQ_4:70;
A79: Wmin in rng go by A61,FINSEQ_6:42;
  set pion = <*Gij,Gi1k,Gik*>;
A80: now
    let n be Nat;
    assume n in dom pion;
    then n in {1,2,3} by FINSEQ_1:89,FINSEQ_3:1;
    then n = 1 or n = 2 or n = 3 by ENUMSET1:def 1;
    hence
    ex i,j be Nat st [i,j] in Indices G & pion/.n = G*(i,j)
    by A17,A18,A19,FINSEQ_4:18;
  end;
A81: Gi1k`1 = G*(i1,1)`1 by A3,A6,A10,A16,GOBOARD5:2
    .= Gij`1 by A3,A4,A10,A15,GOBOARD5:2;
  Gi1k`2 = G*(1,k)`2 by A3,A6,A10,A16,GOBOARD5:1
    .= Gik`2 by A1,A6,A11,A16,GOBOARD5:1;
  then
A82: Gi1k = |[Gij`1,Gik`2]| by A81,EUCLID:53;
A83: Gi1k in pio by RLTOPSP1:68;
A84: Gi1k in poz by RLTOPSP1:68;
  now per cases;
    suppose Gik`1 <> Gij`1 & Gik`2 <> Gij`2;
      then pion is being_S-Seq by A82,TOPREAL3:34;
      then consider pion1 be FinSequence of TOP-REAL 2 such that
A85:  pion1 is_sequence_on G and
A86:  pion1 is being_S-Seq and
A87:  L~pion = L~pion1 and
A88:  pion/.1 = pion1/.1 and
A89:  pion/.len pion = pion1/.len pion1 and
A90:  len pion <= len pion1 by A80,GOBOARD3:2;
      reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A86;
      set godo = go^'pion1^'co;
A91:  Gi1k`1 = G*(i1,1)`1 by A3,A6,A10,A16,GOBOARD5:2
        .= Gij`1 by A3,A4,A10,A15,GOBOARD5:2;
A92:  Gik`1 <= Gi1k`1 by A1,A2,A3,A6,A16,JORDAN1A:18;
      then
A93:  W-bound poz = Gik`1 by SPRECT_1:54;
A94:  W-bound pio = Gij`1 by A91,SPRECT_1:54;
      W-bound (poz \/ pio) = min(W-bound poz, W-bound pio) by SPRECT_1:47
        .= Gik`1 by A91,A92,A93,A94,XXREAL_0:def 9;
      then
A95:  W-bound L~pion1 = Gik`1 by A87,TOPREAL3:16;
A96:  1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A97:  1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
      len (go^'pion1) >= len go by TOPREAL8:7;
      then
A98:  len (go^'pion1) >= 1+1 by A35,XXREAL_0:2;
      then
A99:  len (go^'pion1) > 1+0 by NAT_1:13;
A100: len godo >= len (go^'pion1) by TOPREAL8:7;
      then
A101: 1+1 <= len godo by A98,XXREAL_0:2;
A102: US is_sequence_on G by JORDAN1G:4;
A103: go/.len go = pion1/.1 by A43,A88,FINSEQ_4:18;
      then
A104: go^'pion1 is_sequence_on G by A37,A85,TOPREAL8:12;
A105: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A89,FINSEQ_6:156
        .= pion/.3 by FINSEQ_1:45
        .= co/.1 by A44,FINSEQ_4:18;
      then
A106: godo is_sequence_on G by A40,A104,TOPREAL8:12;
      LSeg(pion1,1) c= L~pion by A87,TOPREAL3:19;
      then
A107: LSeg(go,len go-'1) /\ LSeg(pion1,1) c={Gij} by A46,A53,XBOOLE_1:27;
      len pion1 >= 2+1 by A90,FINSEQ_1:45;
      then
A108: len pion1 > 1+1 by NAT_1:13;
      {Gij} c= LSeg(go,m) /\ LSeg(pion1,1)
      proof
        let x be object;
        assume x in {Gij};
        then
A109:   x = Gij by TARSKI:def 1;
A110:   Gij in LSeg(go,m) by A50,RLTOPSP1:68;
        Gij in LSeg(pion1,1) by A43,A103,A108,TOPREAL1:21;
        hence thesis by A109,A110,XBOOLE_0:def 4;
      end;
      then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go }
      by A43,A46,A107;
      then
A111: go^'pion1 is unfolded by A103,TOPREAL8:34;
      len pion1 >= 2+1 by A90,FINSEQ_1:45;
      then
A112: len pion1-2 >= 0 by XREAL_1:19;
      len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
      then len (go^'pion1)-1 = len go + (len pion1-2)
        .= len go + (len pion1-'2) by A112,XREAL_0:def 2;
      then
A113: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A114: len pion1-1 >= 1 by A108,XREAL_1:19;
      then
A115: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A116: len pion1-'2+1 = len pion1-2+1 by A112,XREAL_0:def 2
        .= len pion1-'1 by A114,XREAL_0:def 2;
      len pion1-1+1 <= len pion1;
      then
A117: len pion1-'1 < len pion1 by A115,NAT_1:13;
      LSeg(pion1,len pion1-'1) c= L~pion by A87,TOPREAL3:19;
      then
A118: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gik} by A60,XBOOLE_1:27;
      {Gik} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
      proof
        let x be object;
        assume x in {Gik};
        then
A119:   x = Gik by TARSKI:def 1;
A120:   Gik in LSeg(co,1) by A57,RLTOPSP1:68;
        pion1/.(len pion1-'1+1) = pion/.3 by A89,A115,FINSEQ_1:45
          .= Gik by FINSEQ_4:18;
        then Gik in LSeg(pion1,len pion1-'1) by A114,A115,TOPREAL1:21;
        hence thesis by A119,A120,XBOOLE_0:def 4;
      end;
      then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gik}
      by A118;
      then
A121: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) =
      {(go^'pion1)/.len (go^'pion1)} by A44,A103,A105,A116,A117,TOPREAL8:31;
A122: (go^'pion1) is non trivial by A98,NAT_D:60;
A123: rng pion1 c= L~pion1 by A108,SPPOL_2:18;
A124: {pion1/.1} c= L~go /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.1};
        then
A125:   x = pion1/.1 by TARSKI:def 1;
        then
A126:   x in rng go by A103,FINSEQ_6:168;
        x in rng pion1 by A125,FINSEQ_6:42;
        hence thesis by A63,A123,A126,XBOOLE_0:def 4;
      end;
      L~go /\ L~pion1 c= {pion1/.1}
      proof
        let x be object;
        assume
A127:   x in L~go /\ L~pion1;
        then
A128:   x in L~go by XBOOLE_0:def 4;
        x in L~pion1 by A127,XBOOLE_0:def 4;
        hence thesis by A7,A12,A43,A48,A87,A103,A128,XBOOLE_0:def 4;
      end;
      then
A129: L~go /\ L~pion1 = {pion1/.1} by A124;
      then
A130: (go^'pion1) is s.n.c. by A103,JORDAN1J:54;
      rng go /\ rng pion1 c= {pion1/.1} by A63,A123,A129,XBOOLE_1:27;
      then
A131: go^'pion1 is one-to-one by JORDAN1J:55;
A132: pion/.len pion = pion/.3 by FINSEQ_1:45
        .= co/.1 by A44,FINSEQ_4:18;
A133: {pion1/.len pion1} c= L~co /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.len pion1};
        then
A134:   x = pion1/.len pion1 by TARSKI:def 1;
        then
A135:   x in rng co by A89,A132,FINSEQ_6:42;
        x in rng pion1 by A134,FINSEQ_6:168;
        hence thesis by A64,A123,A135,XBOOLE_0:def 4;
      end;
      L~co /\ L~pion1 c= {pion1/.len pion1}
      proof
        let x be object;
        assume
A136:   x in L~co /\ L~pion1;
        then
A137:   x in L~co by XBOOLE_0:def 4;
        x in L~pion1 by A136,XBOOLE_0:def 4;
        hence thesis by A8,A12,A44,A55,A87,A89,A132,A137,XBOOLE_0:def 4;
      end;
      then
A138: L~co /\ L~pion1 = {pion1/.len pion1} by A133;
A139: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A103,TOPREAL8:35
        .= {go/.1} \/ {co/.1} by A75,A89,A132,A138,XBOOLE_1:23
        .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
        .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
      co/.len co = (go^'pion1)/.1 by A62,FINSEQ_6:155;
      then reconsider godo as non constant standard special_circular_sequence
      by A101,A105,A106,A111,A113,A121,A122,A130,A131,A139,JORDAN8:4,5
,TOPREAL8:11,33,34;
A140: UA is_an_arc_of W-min C,E-max C by JORDAN6:def 8;
      then
A141: UA is connected by JORDAN6:10;
A142: W-min C in UA by A140,TOPREAL1:1;
A143: E-max C in UA by A140,TOPREAL1:1;
      set ff = Rotate(Cage(C,n),Wmin);
      Wmin in rng Cage(C,n) by SPRECT_2:43;
      then
A144: ff/.1 = Wmin by FINSEQ_6:92;
A145: L~ff = L~Cage(C,n) by REVROT_1:33;
      then (W-max L~ff)..ff > 1 by A144,SPRECT_5:22;
      then (N-min L~ff)..ff > 1 by A144,A145,SPRECT_5:23,XXREAL_0:2;
      then (N-max L~ff)..ff > 1 by A144,A145,SPRECT_5:24,XXREAL_0:2;
      then
A146: Emax..ff > 1 by A144,A145,SPRECT_5:25,XXREAL_0:2;
A147: now
        assume
A148:   Gij..US <= 1;
        Gij..US >= 1 by A36,FINSEQ_4:21;
        then Gij..US = 1 by A148,XXREAL_0:1;
        then Gij = US/.1 by A36,FINSEQ_5:38;
        hence contradiction by A22,A26,JORDAN1F:5;
      end;
A149: Cage(C,n) is_sequence_on G by JORDAN9:def 1;
      then
A150: ff is_sequence_on G by REVROT_1:34;
A151: right_cell(godo,1,G)\L~godo c= RightComp godo by A101,A106,JORDAN9:27;
A152: L~godo = L~(go^'pion1) \/ L~co by A105,TOPREAL8:35
        .= L~go \/ L~pion1 \/ L~co by A103,TOPREAL8:35;
A153: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
      then
A154: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A155: L~LS c= L~Cage(C,n) by A153,XBOOLE_1:7;
A156: L~go c=L~Cage(C,n) by A48,A154;
A157: L~co c=L~Cage(C,n) by A55,A155;
A158: W-min C in C by SPRECT_1:13;
A159: now
        assume W-min C in L~godo;
        then
A160:   W-min C in L~go \/ L~pion1 or W-min C in L~co by A152,XBOOLE_0:def 3;
        per cases by A160,XBOOLE_0:def 3;
        suppose W-min C in L~go;
          then C meets L~Cage(C,n) by A156,A158,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
        suppose W-min C in L~pion1;
          hence contradiction by A9,A12,A87,A142,XBOOLE_0:3;
        end;
        suppose W-min C in L~co;
          then C meets L~Cage(C,n) by A157,A158,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
      end;
      right_cell(Rotate(Cage(C,n),Wmin),1) =
      right_cell(ff,1,GoB ff) by A97,JORDAN1H:23
        .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
        .= right_cell(ff,1,G) by JORDAN1H:44
        .= right_cell(ff-:Emax,1,G) by A146,A150,JORDAN1J:53
        .= right_cell(US,1,G) by JORDAN1E:def 1
        .= right_cell(R_Cut(US,Gij),1,G) by A36,A102,A147,JORDAN1J:52
        .= right_cell(go^'pion1,1,G) by A41,A104,JORDAN1J:51
        .= right_cell(godo,1,G) by A99,A106,JORDAN1J:51;
      then W-min C in right_cell(godo,1,G) by JORDAN1I:6;
      then
A161: W-min C in right_cell(godo,1,G)\L~godo by A159,XBOOLE_0:def 5;
A162: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
        .= Wmin by A61,FINSEQ_6:155;
A163: len US >= 2 by A21,XXREAL_0:2;
A164: godo/.2 = (go^'pion1)/.2 by A98,FINSEQ_6:159
        .= US/.2 by A35,A78,FINSEQ_6:159
        .= (US^'LS)/.2 by A163,FINSEQ_6:159
        .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A165: L~go \/ L~co is compact by COMPTS_1:10;
      Wmin in L~go \/ L~co by A63,A79,XBOOLE_0:def 3;
      then
A166: W-min (L~go \/ L~co) = Wmin by A156,A157,A165,JORDAN1J:21,XBOOLE_1:8;
A168: Wmin`1 = Wbo;
      Gik`1 >= Wbo by A13,A155,PSCOMP_1:24;
      then Gik`1 > Wbo by A77,XXREAL_0:1;
      then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co)
      by A95,A165,A166,A168,JORDAN1J:33;
      then
A169: W-min L~godo = Wmin by A152,A166,XBOOLE_1:4;
A170: rng godo c= L~godo by A98,A100,SPPOL_2:18,XXREAL_0:2;
      2 in dom godo by A101,FINSEQ_3:25;
      then
A171: godo/.2 in rng godo by PARTFUN2:2;
      godo/.2 in W-most L~Cage(C,n) by A164,JORDAN1I:25;
      then (godo/.2)`1 = (W-min L~godo)`1 by A169,PSCOMP_1:31
        .= W-bound L~godo;
      then godo/.2 in W-most L~godo by A170,A171,SPRECT_2:12;
      then Rotate(godo,W-min L~godo)/.2 in W-most L~godo
      by A162,A169,FINSEQ_6:89;
      then reconsider godo as clockwise_oriented non constant standard
      special_circular_sequence by JORDAN1I:25;
      len US in dom US by FINSEQ_5:6;
      then
A172: US.len US = US/.len US by PARTFUN1:def 6
        .= Emax by JORDAN1F:7;
A173: east_halfline E-max C misses L~go
      proof
        assume east_halfline E-max C meets L~go;
        then consider p be object such that
A174:   p in east_halfline E-max C and
A175:   p in L~go by XBOOLE_0:3;
        reconsider p as Point of TOP-REAL 2 by A174;
        p in L~US by A48,A175;
        then p in east_halfline E-max C /\ L~Cage(C,n)
        by A154,A174,XBOOLE_0:def 4;
        then
   p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
        then
   p = Emax by A48,A175,JORDAN1J:46;
        then Emax = Gij by A14,A172,A175,JORDAN1J:43;
        then Gij`1 = G*(len G,k)`1 by A6,A16,A20,JORDAN1A:71;
        hence contradiction by A3,A17,A32,JORDAN1G:7;
      end;
      now
        assume east_halfline E-max C meets L~godo;
        then
A178:   east_halfline E-max C meets (L~go \/ L~pion1) or
        east_halfline E-max C meets L~co by A152,XBOOLE_1:70;
        per cases by A178,XBOOLE_1:70;
        suppose east_halfline E-max C meets L~go;
          hence contradiction by A173;
        end;
        suppose east_halfline E-max C meets L~pion1;
          then consider p be object such that
A179:     p in east_halfline E-max C and
A180:     p in L~pion1 by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A179;
A181:     now per cases by A12,A87,A180,XBOOLE_0:def 3;
            suppose p in poz;
              hence p`1 <= Gij`1 by A91,A92,TOPREAL1:3;
            end;
            suppose p in pio;
              hence p`1 <= Gij`1 by A91,GOBOARD7:5;
            end;
          end;
          i1+1 <= len G by A3,NAT_1:13;
          then i1 <= len G-1 by XREAL_1:19;
          then
A182:     i1 <= len G-'1 by XREAL_0:def 2;
          len G-'1 <= len G by NAT_D:35;
          then Gij`1 <= G*(len G-'1,1)`1 by A4,A10,A15,A20,A24,A182,JORDAN1A:18
;
          then p`1 <= G*(len G-'1,1)`1 by A181,XXREAL_0:2;
          then p`1 <= E-bound C by A24,JORDAN8:12;
          then
A183:     p`1 <= (E-max C)`1;
          p`1 >= (E-max C)`1 by A179,TOPREAL1:def 11;
          then
A184:     p`1 = (E-max C)`1 by A183,XXREAL_0:1;
          p`2 = (E-max C)`2 by A179,TOPREAL1:def 11;
          then p = E-max C by A184,TOPREAL3:6;
          hence contradiction by A9,A12,A87,A143,A180,XBOOLE_0:3;
        end;
        suppose east_halfline E-max C meets L~co;
          then consider p be object such that
A185:     p in east_halfline E-max C and
A186:     p in L~co by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A185;
          p in L~LS by A55,A186;
          then p in east_halfline E-max C /\ L~Cage(C,n)
          by A155,A185,XBOOLE_0:def 4;
          then
A187:     p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A188:     (E-max C)`2 = p`2 by A185,TOPREAL1:def 11;
          set RC = Rotate(Cage(C,n),Emax);
A189:     E-max C in right_cell(RC,1) by JORDAN1I:7;
A190:     1+1 <= len LS by A27,XXREAL_0:2;
          LS = RC-:Wmin by JORDAN1G:18;
          then
A191:     LSeg(LS,1) = LSeg(RC,1) by A190,SPPOL_2:9;
A192:     L~RC = L~Cage(C,n) by REVROT_1:33;
A193:     len RC = len Cage(C,n) by FINSEQ_6:179;
A194:     GoB RC = GoB Cage(C,n) by REVROT_1:28
            .= G by JORDAN1H:44;
A195:     Emax in rng Cage(C,n) by SPRECT_2:46;
A196:     RC is_sequence_on G by A149,REVROT_1:34;
A197:     RC/.1 = E-max L~RC by A192,A195,FINSEQ_6:92;
          consider ii,jj be Nat such that
A198:     [ii,jj+1] in Indices G and
A199:     [ii,jj] in Indices G and
A200:     RC/.1 = G*(ii,jj+1) and
A201:     RC/.(1+1) = G*(ii,jj) by A96,A192,A193,A195,A196,FINSEQ_6:92
,JORDAN1I:23;
          consider jj2 be Nat such that
A202:     1 <= jj2 and
A203:     jj2 <= width G and
A204:     Emax = G*(len G,jj2) by JORDAN1D:25;
A205:     len G >= 4 by JORDAN8:10;
          then len G >= 1 by XXREAL_0:2;
          then [len G,jj2] in Indices G by A202,A203,MATRIX_0:30;
          then
A206:     ii = len G by A192,A197,A198,A200,A204,GOBOARD1:5;
A207:     1 <= ii by A198,MATRIX_0:32;
A208:     ii <= len G by A198,MATRIX_0:32;
A209:     1 <= jj+1 by A198,MATRIX_0:32;
A210:     jj+1 <= width G by A198,MATRIX_0:32;
A211:     1 <= ii by A199,MATRIX_0:32;
A212:     ii <= len G by A199,MATRIX_0:32;
A213:     1 <= jj by A199,MATRIX_0:32;
A214:     jj <= width G by A199,MATRIX_0:32;
A215:     ii+1 <> ii;
          jj+1+1 <> jj;
          then
A216:     right_cell(RC,1) = cell(G,ii-'1,jj)
          by A96,A193,A194,A198,A199,A200,A201,A215,GOBOARD5:def 6;
A217:     ii-'1+1 = ii by A207,XREAL_1:235;
          ii-1 >= 4-1 by A205,A206,XREAL_1:9;
          then
A218:     ii-1 >= 1 by XXREAL_0:2;
          then
A219:     1 <= ii-'1 by XREAL_0:def 2;
A220:     G*(ii-'1,jj)`2 <= p`2 by A188,A189,A208,A210,A213,A216,A217,A218,
JORDAN9:17;
A221:     p`2 <= G*(ii-'1,jj+1)`2 by A188,A189,A208,A210,A213,A216,A217,A218,
JORDAN9:17;
A222:     ii-'1 < len G by A208,A217,NAT_1:13;
          then
A223:     G*(ii-'1,jj)`2 = G*(1,jj)`2 by A213,A214,A219,GOBOARD5:1
            .= G*(ii,jj)`2 by A211,A212,A213,A214,GOBOARD5:1;
A224:     G*(ii-'1,jj+1)`2 = G*(1,jj+1)`2 by A209,A210,A219,A222,GOBOARD5:1
            .= G*(ii,jj+1)`2 by A207,A208,A209,A210,GOBOARD5:1;
A225:     G*(len G,jj)`1 = Ebo by A20,A213,A214,JORDAN1A:71;
          Ebo = G*(len G,jj+1)`1 by A20,A209,A210,JORDAN1A:71;
          then p in LSeg(RC/.1,RC/.(1+1))
          by A187,A200,A201,A206,A220,A221,A223,A224,A225,GOBOARD7:7;
          then
A226:     p in LSeg(LS,1) by A96,A191,A193,TOPREAL1:def 3;
A227:     p in LSeg(co,Index(p,co)) by A186,JORDAN3:9;
A228:     co = mid(LS,Gik..LS,len LS) by A39,JORDAN1J:37;
A229:     1<=Gik..LS by A39,FINSEQ_4:21;
A230:     Gik..LS<=len LS by A39,FINSEQ_4:21;
          Gik..LS <> len LS by A31,A39,FINSEQ_4:19;
          then
A231:     Gik..LS < len LS by A230,XXREAL_0:1;
A232:     1<=Index(p,co) by A186,JORDAN3:8;
A233:     Index(p,co) < len co by A186,JORDAN3:8;
A234:     Index(Gik,LS)+1 = Gik..LS by A34,A39,JORDAN1J:56;
          consider t be Nat such that
A235:     t in dom LS and
A236:     LS.t = Gik by A39,FINSEQ_2:10;
A237:     1 <= t by A235,FINSEQ_3:25;
A238:     t <= len LS by A235,FINSEQ_3:25;
          1 < t by A34,A236,A237,XXREAL_0:1;
          then Index(Gik,LS)+1 = t by A236,A238,JORDAN3:12;
          then
A239:     len L_Cut(LS,Gik) = len LS-Index(Gik,LS) by A13,A236,JORDAN3:26;
          set tt = Index(p,co)+(Gik..LS)-'1;
A240:     1<=Index(Gik,LS) by A13,JORDAN3:8;
          0+Index(Gik,LS) < len LS by A13,JORDAN3:8;
          then
A241:     len LS-Index(Gik,LS) > 0 by XREAL_1:20;
          Index(p,co) < len LS-'Index(Gik,LS) by A233,A239,XREAL_0:def 2;
          then Index(p,co)+1 <= len LS-'Index(Gik,LS) by NAT_1:13;
          then Index(p,co) <= len LS-'Index(Gik,LS)-1 by XREAL_1:19;
          then Index(p,co) <= len LS-Index(Gik,LS)-1 by A241,XREAL_0:def 2;
          then Index(p,co) <= len LS-Gik..LS by A234;
          then Index(p,co) <= len LS-'Gik..LS by XREAL_0:def 2;
          then Index(p,co) < len LS-'(Gik..LS)+1 by NAT_1:13;
          then
A242:     LSeg(mid(LS,Gik..LS,len LS),Index(p,co)) =
          LSeg(LS,Index(p,co)+(Gik..LS)-'1) by A229,A231,A232,JORDAN4:19;
A243:     1+1 <= Gik..LS by A234,A240,XREAL_1:7;
          then Index(p,co)+Gik..LS >= 1+1+1 by A232,XREAL_1:7;
          then Index(p,co)+Gik..LS-1 >= 1+1+1-1 by XREAL_1:9;
          then
A244:     tt >= 1+1 by XREAL_0:def 2;
A245:     2 in dom LS by A190,FINSEQ_3:25;
          now per cases by A244,XXREAL_0:1;
            suppose tt > 1+1;
              then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
              hence contradiction by A226,A227,A228,A242,XBOOLE_0:3;
            end;
            suppose
A246:         tt = 1+1;
              then LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A27,TOPREAL1:def 6;
              then p in {LS/.2} by A226,A227,A228,A242,XBOOLE_0:def 4;
              then
A247:         p = LS/.2 by TARSKI:def 1;
              then
A248:         p..LS = 2 by A245,FINSEQ_5:41;
              1+1 = Index(p,co)+(Gik..LS)-1 by A246,XREAL_0:def 2;
              then 1+1+1 = Index(p,co)+(Gik..LS);
              then
A249:         Gik..LS = 2 by A232,A243,JORDAN1E:6;
              p in rng LS by A245,A247,PARTFUN2:2;
              then p = Gik by A39,A248,A249,FINSEQ_5:9;
              then Gik`1 = Ebo by A247,JORDAN1G:32;
              then Gik`1 = G*(len G,j)`1 by A4,A15,A20,JORDAN1A:71;
              hence contradiction by A2,A3,A18,A69,JORDAN1G:7;
            end;
          end;
          hence contradiction;
        end;
      end;
      then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
      then consider W be Subset of TOP-REAL 2 such that
A250: W is_a_component_of (L~godo)` and
A251: east_halfline E-max C c= W by GOBOARD9:3;
      W is not bounded by A251,JORDAN2C:121,RLTOPSP1:42;
      then W is_outside_component_of L~godo by A250,JORDAN2C:def 3;
      then W c= UBD L~godo by JORDAN2C:23;
      then
A252: east_halfline E-max C c= UBD L~godo by A251;
      E-max C in east_halfline E-max C by TOPREAL1:38;
      then E-max C in UBD L~godo by A252;
      then E-max C in LeftComp godo by GOBRD14:36;
      then UA meets L~godo by A141,A142,A143,A151,A161,JORDAN1J:36;
      then
A253: UA meets (L~go \/ L~pion1) or UA meets L~co by A152,XBOOLE_1:70;
A254: UA c= C by JORDAN6:61;
      now per cases by A253,XBOOLE_1:70;
        suppose UA meets L~go;
          then UA meets L~Cage(C,n) by A48,A154,XBOOLE_1:1,63;
          hence contradiction by A254,JORDAN10:5,XBOOLE_1:63;
        end;
        suppose UA meets L~pion1;
          hence contradiction by A9,A12,A87;
        end;
        suppose UA meets L~co;
          then UA meets L~Cage(C,n) by A55,A155,XBOOLE_1:1,63;
          hence contradiction by A254,JORDAN10:5,XBOOLE_1:63;
        end;
      end;
      hence contradiction;
    end;
    suppose Gik`1 = Gij`1;
      then
A255: i1 = i2 by A17,A18,JORDAN1G:7;
      then poz = {Gi1k} by RLTOPSP1:70;
      then poz c= pio by A83,ZFMISC_1:31;
      then pio \/ poz = pio by XBOOLE_1:12;
      hence contradiction by A1,A3,A4,A5,A6,A7,A8,A9,A255,Th12;
    end;
    suppose Gik`2 = Gij`2;
      then
A256: j = k by A17,A18,JORDAN1G:6;
      then pio = {Gi1k} by RLTOPSP1:70;
      then pio c= poz by A84,ZFMISC_1:31;
      then pio \/ poz = poz by XBOOLE_1:12;
      hence contradiction by A1,A2,A3,A4,A6,A7,A8,A9,A256,JORDAN15:29;
    end;
  end;
  hence contradiction;
end;
