reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th22:
  0 < n implies LMP L~Cage(C,n) = LMP Lower_Arc L~Cage(C,n)
proof
  set f = Cage(C,n);
  set w = (E-bound C + W-bound C) / 2;
A1: Lower_Arc L~f c= L~f by JORDAN6:61;
A2: W-bound C + E-bound C = W-bound L~f + E-bound L~f by JORDAN1G:33;
A3: E-bound L~f = E-bound Lower_Arc L~f by JORDAN21:20;
A4: W-bound L~f = W-bound Lower_Arc L~f by JORDAN21:19;
  assume
A5: 0 < n;
  then
A6: 0+1 <= n by NAT_1:13;
  then
A7: n-'1+1 = n by XREAL_1:235;
A8: now
A9: Center Gauge(C,1) <= len Gauge(C,1) by JORDAN1B:13;
A10: len Gauge(C,n) = width Gauge(C,n) by JORDAN8:def 1;
A11: Upper_Arc L~f \/ Lower_Arc L~f = L~f by JORDAN6:def 9;
    assume
A12: not LMP L~f in Lower_Arc L~f;
    consider j being Nat such that
A13: 1 <= j and
A14: j <= len Gauge(C,n) and
A15: LMP L~f = Gauge(C,n)*(Center Gauge(C,n),j) by A5,Th20;
    set a = Gauge(C,1)*(Center Gauge(C,1),1), b = Gauge(C,n)*(Center Gauge(C,n
    ),j), L = LSeg(a,b);
A16: a in L by RLTOPSP1:68;
    LMP L~f in L~f by JORDAN21:31;
    then LMP L~f in Upper_Arc L~f by A12,A11,XBOOLE_0:def 3;
    then L meets Lower_Arc L~f by A7,A13,A14,A15,A10,JORDAN1J:62;
    then consider x being object such that
A17: x in L and
A18: x in Lower_Arc L~f by XBOOLE_0:3;
    reconsider x as Point of TOP-REAL 2 by A17;
A19: 1 <= Center Gauge(C,n) by JORDAN1B:11;
A20: 1 <= len Gauge(C,1) by Lm3;
    then
A21: a`1 = w by JORDAN1A:38;
    then
A22: b`1 = w by A5,A13,A14,A20,JORDAN1A:36;
    then L is vertical by A21,SPPOL_1:16;
    then
A23: x`1 = w by A17,A21,A16,SPPOL_1:def 3;
    then x in Vertical_Line w;
    then
A24: x in Lower_Arc L~f /\ Vertical_Line w by A18,XBOOLE_0:def 4;
    then
A25: (LMP Lower_Arc L~f)`2 <= x`2 by A2,A4,A3,JORDAN21:29;
A26: Center Gauge(C,n) <= len Gauge(C,n) by JORDAN1B:13;
    1 <= Center Gauge(C,1) by JORDAN1B:11;
    then
A27: Gauge(C,1)*(Center Gauge(C,1),1)`2 <= Gauge(C,n)*(Center Gauge(C, n)
    ,1)`2 by A6,A19,A26,A9,JORDAN1A:43;
    Gauge(C,n)*(Center Gauge(C,n),1)`2 <= Gauge(C,n)*(Center Gauge(C,n),j
    ) `2 by A13,A14,A10,A19,A26,SPRECT_3:12;
    then a`2 <= b`2 by A27,XXREAL_0:2;
    then
A28: x`2 <= b`2 by A17,TOPREAL1:4;
    (LMP L~f)`2 <= (LMP Lower_Arc L~f)`2 by A1,A2,A4,A3,A24,JORDAN21:13,44;
    then b`2 <= x`2 by A15,A25,XXREAL_0:2;
    then b`2 = x`2 by A28,XXREAL_0:1;
    hence contradiction by A12,A15,A18,A22,A23,TOPREAL3:6;
  end;
  proj2.:(L~f /\ Vertical_Line w) is bounded_below by A2,JORDAN21:13;
  hence thesis by A1,A2,A4,A3,A8,JORDAN21:22,46;
end;
