reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;

theorem
  X (-) {x} = X+(-x)
proof
  thus X (-) {x} c= X+(-x)
  proof
    let y be object;
    assume y in X (-) {x};
    then consider p being Point of T such that
A1: p=y and
A2: {x}+p c= X;
    {p}+x c= X by A2,Lm1;
    then {p}+x+(-x) c= X+(-x) by Th3;
    then {p}+(x+(-x)) c= X+(-x) by Th16;
    then {p}+0.T c= X+(-x) by RLVECT_1:5;
    then {p} c= X+(-x) by Th21;
    hence thesis by A1,ZFMISC_1:31;
  end;
  let y be object;
  assume y in X+(-x);
  then consider p being Point of T such that
A3: y=p+(-x) and
A4: p in X;
  reconsider y as Point of T by A3;
  y = p - x by A3;
  then
A5: y+x = p by Lm2;
  {x}+y c= X
  proof
    let q be object;
    assume q in {x}+y;
    then consider qq being Point of T such that
A6: q=qq+y and
A7: qq in {x};
    {qq} c= {x} by A7,ZFMISC_1:31;
    hence thesis by A4,A5,A6,ZFMISC_1:18;
  end;
  hence thesis;
end;
