reserve x,y,x1,x2,z for set,
  n,m,k for Nat,
  t1 for (DecoratedTree of [: NAT,NAT :]),
  w,s,t,u for FinSequence of NAT,
  D for non empty set;
reserve s9,w9,v9 for Element of NAT*;

theorem Th17:
  for Z being finite Tree,z being Element of Z st succ (Root Z) =
  {z} holds Z = elementary_tree 1 with-replacement (<*0*>,Z|z)
proof
  let Z be finite Tree,z be Element of Z;
  set e = elementary_tree 1;
A1: <*0*> in e by TARSKI:def 2,TREES_1:51;
A2: {} in Z by TREES_1:22;
  assume
A3: succ (Root Z) = {z};
  then card succ (Root Z) = 1 by CARD_1:30;
  then branchdeg (Root Z) = 1 by TREES_2:def 12;
  then {z} = { <*0*> } by A3,Th13;
  then z in { <*0*> } by TARSKI:def 1;
  then
A4: z = <*0*> by TARSKI:def 1;
  then
A5: <*0*> in Z;
  now
    let x be object;
    thus x in Z implies x in e with-replacement (<*0*>,Z|z)
    proof
      assume x in Z;
      then reconsider x9 = x as Element of Z;
      per cases;
      suppose
        x9 = {};
        hence thesis by TREES_1:22;
      end;
      suppose
        x9 <> {};
        then consider w be FinSequence of NAT,
        n being Element of NAT such that
A6:     x9 = <*n*>^w by FINSEQ_2:130;
        <*n*> is_a_prefix_of x9 by A6,TREES_1:1;
        then
A7:     <*n*> in Z by TREES_1:20;
        <*n*> = (Root Z)^<*n*> by FINSEQ_1:34;
        then
A8:     <*n*> in succ (Root Z) by A7,TREES_2:12;
        then <*n*> = z by A3,TARSKI:def 1;
        then
A9:     w in Z|z by A6,TREES_1:def 6;
        <*n*> = <*0*> by A3,A4,A8,TARSKI:def 1;
        hence thesis by A1,A6,A9,TREES_1:def 9;
      end;
    end;
    assume x in e with-replacement (<*0*>,Z|z);
    then reconsider x9 = x as Element of e with-replacement (<*0*>,Z|z);
    per cases by A1,TREES_1:def 9;
    suppose
      x9 in e & not <*0*> is_a_proper_prefix_of x9;
      hence x in Z by A5,A2,TARSKI:def 2,TREES_1:51;
    end;
    suppose
      ex s st s in Z|z & x9 = <*0*>^s;
      hence x in Z by A4,TREES_1:def 6;
    end;
  end;
  hence thesis by TARSKI:2;
end;
