 reserve n,i,k,m for Nat;
 reserve p for Prime;

theorem
  for n being non zero Nat holds
    ln.(n + 1) < Harmonic n
  proof
    let n be non zero Nat;
    set A = [.1, n+1.];
    0 + 1 <= n + 1 by XREAL_1:31; then
    reconsider A as non empty closed_interval Subset of REAL
      by MEASURE5:def 3,XXREAL_1:1;
WA: A = [' 1, n + 1 '] by XREAL_1:31,INTEGRA5:def 3;
    reconsider Z = right_open_halfline 0 as open Subset of REAL;
N1: not 0 in Z by XXREAL_1:4;
A1: A c= Z
    proof
      let x be object;
      assume
a1:   x in A; then
      reconsider xx = x as Real;
      1 <= xx & xx <= n + 1 by a1,XXREAL_1:1;
      hence thesis by XXREAL_1:235;
    end;
    set f = id Z;
NN: dom (f^) = dom f \ f"{0} by RFUNCT_1:def 2
            .= Z \ {} by Counter0,N1
            .= Z;
B1: lower_bound A = 1 by XREAL_1:31,XXREAL_2:25;
B2: upper_bound A = n + 1 by XREAL_1:31,XXREAL_2:29;
    (id Z)^ | A is continuous by ContCut,A1,N1; then
KL: integral ((id Z)^,A) = ln.(upper_bound A) - ln.(lower_bound A)
      by A1,TAYLOR_1:18,NN,INTEGRA9:61
        .= ln.(n + 1) - (1 - 1) by ENTROPY1:2,B1,B2
        .= ln.(n + 1);
    set g = (id Z)^;
    defpred P[Nat] means
      integral (g,1,$1 + 1) < Harmonic $1;
    reconsider AA = ['1,1+1'] as non empty closed_interval Subset of REAL;
    AA = [.1,1+1.] by INTEGRA5:def 3; then
    integral (g, AA) < 1 / 1 by Diesel3; then
I1: P[1] by Harm1,INTEGRA5:def 4;
I2: for k being non zero Nat st P[k] holds P[k+1]
    proof
      let k be non zero Nat;
      assume s0: P[k];
      set a = 1, b = k + 1 + 1, c = k + 1;
W0:   a <= b by XREAL_1:31;
Za:   [. a,b .] c= ]. 0, +infty .[ by XXREAL_1:249; then
W3:   [' a,b '] c= dom g by XREAL_1:31,INTEGRA5:def 3,NN;
      set B = [' a, b '];
      B c= Z by Za,INTEGRA5:def 3,XREAL_1:31; then
v1:   ((id Z)^) | B is continuous by ContCut,N1; then
W2:   g is_integrable_on [' a,b '] by INTEGRA5:11,W3;
W4:   g | [' a,b '] is bounded by INTEGRA5:10,W3,v1;
      a <= c & c <= b by XREAL_1:31; then
      c in [. a,b .] by XXREAL_1:1; then
      c in [' a,b '] by XREAL_1:31,INTEGRA5:def 3; then
W1:   integral(g,a,b) = integral(g,a,c) + integral(g,c,b)
        by W0,W2,W3,W4,INTEGRA6:17;
      set AB = ['k+1, k+1+1'];
      AB = [.k+1, k+1+1.] by INTEGRA5:def 3,NAT_1:11; then
      integral (g,AB) < 1 / (k + 1) by Diesel3; then
      integral (g,k + 1, k + 1 + 1) < 1 / (k + 1)
        by NAT_1:11,INTEGRA5:def 4; then
      integral (g,1,k + 1) + integral (g,k + 1, k + 1 + 1) <
        Harmonic k + 1 / (k + 1) by s0,XREAL_1:8;
      hence thesis by Harmon1,W1;
    end;
KK: for n being non zero Nat holds P[n] from NAT_1:sch 10(I1,I2);
    integral (g,1,n + 1) < Harmonic n by KK;
    hence thesis by KL,INTEGRA5:def 4,WA,XREAL_1:31;
  end;
