reserve S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem NORMSP31:
  for X,Y be RealNormSpace,
      x be Point of X,
      y be Point of Y,
      z be Point of [:X,Y:],
      r1 be Real
    st 0 < r1 & z = [x,y]
  holds
    ex r2 be Real
    st 0 < r2 & r2 < r1 & [:Ball(x,r2),Ball(y,r2):] c= Ball(z,r1)
  proof
    let X,Y be RealNormSpace,
          x be Point of X,
          y be Point of Y,
          z be Point of [:X,Y:],
          r1 be Real;
    assume
    A1: 0 < r1 & z = [x,y];
    take r2 = r1/2;
    thus 0<r2 & r2<r1 by A1,XREAL_1:215,XREAL_1:216;
    A2: r1^2 / 2 < r1^2 by A1,SQUARE_1:12,XREAL_1:216;
    thus [:Ball(x,r2),Ball(y,r2):] c= Ball(z,r1)
    proof
      let w be object;
      assume w in [:Ball(x,r2),Ball(y,r2):]; then
      consider x1,y1 be object such that
  A3: x1 in Ball(x,r2) & y1 in Ball(y,r2)
        & w = [x1,y1] by ZFMISC_1:def 2;
      reconsider x1 as Point of X by A3;
      reconsider y1 as Point of Y by A3;
      [x1,y1] is set; then
      reconsider xy = w as Point of [:X,Y:] by A3;
      ex p be Point of X st x1 = p & ||.x - p.|| < r2 by A3; then
  A4: ||.x - x1.||^2 < r2 ^2 by SQUARE_1:16;
      ex p be Point of Y st y1 = p & ||.y - p.|| < r2 by A3; then
  A5: ||.y - y1.||^2 < r2 ^2 by SQUARE_1:16;
      -xy = [-x1,-y1] by A3,PRVECT_3:18; then
      z - xy = [x-x1, y-y1 ] by A1,PRVECT_3:18; then
  A7: ||.z -xy.|| = sqrt (||.x-x1.|| ^2 + ||.y-y1.|| ^2) by LMNR0;
      ||.x-x1.|| ^2 + ||.y-y1.|| ^2 < r2^2 + r2^2 by A4,A5,XREAL_1:8; then
      ||.x-x1.|| ^2 + ||.y-y1.|| ^2 < r1^2 by A2,XXREAL_0:2; then
      sqrt (||.x-x1.|| ^2 + ||.y-y1.|| ^2) < sqrt (r1^2) by SQUARE_1:27; then
      ||.z -xy.|| <r1 by A1,A7,SQUARE_1:22;
      hence w in Ball(z,r1);
    end;
  end;
