reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th22:
  for G being non empty RelStr, H being non empty full SubRelStr
  of G holds G embeds H
proof
  let G be non empty RelStr;
  let H be non empty full SubRelStr of G;
  reconsider f = id the carrier of H as Function of the carrier of H, the
  carrier of H;
A1: dom f = the carrier of H;
A2: the carrier of H c= the carrier of G by YELLOW_0:def 13;
  for x being object st x in the carrier of H holds f.x in the carrier of G
  proof
    let x be object;
    assume x in the carrier of H;
    then f.x in the carrier of H by FUNCT_1:17;
    hence thesis by A2;
  end;
  then reconsider f = id the carrier of H as Function of the carrier of H, the
  carrier of G by A1,FUNCT_2:3;
  reconsider f as Function of H,G;
  for x,y being Element of H holds [x,y] in the InternalRel of H iff [f.x,
  f.y] in the InternalRel of G
  proof
    set IH = the InternalRel of H, IG = the InternalRel of G, cH = the carrier
    of H;
    let x,y be Element of H;
    thus [x,y] in IH implies [f.x,f.y] in IG
    proof
      assume [x,y] in IH;
      then [x,y] in IG |_2 cH by YELLOW_0:def 14;
      hence thesis by XBOOLE_0:def 4;
    end;
    assume [f.x,f.y] in IG;
    then [x,y] in IG |_2 cH by XBOOLE_0:def 4;
    hence thesis by YELLOW_0:def 14;
  end;
  hence thesis;
end;
