 reserve RNS1,RNS2 for RealLinearSpace;

theorem Th22:
for RNS be RealNormSpace
  holds the NORMSTR of RNS is strict RealNormSpace
proof
let l0 be RealNormSpace;
set l = the NORMSTR of l0;
reconsider l as non empty NORMSTR;
A1: l is Abelian
  proof
  let v, w be VECTOR of l;
  reconsider v1 = v, w1 = w as VECTOR of l0;
  thus v+w = v1+w1
          .= w1+v1
          .= w+v;
  end;
A2: l is right_zeroed
  proof
  let v be VECTOR of l;
  reconsider v1 = v as VECTOR of l0;
  thus v+(0.l) = v1+(0.l0)
              .= v;
  end;
A3: l is right_complementable
  proof
  let v be VECTOR of l;
  reconsider v1 = v as VECTOR of l0;
  consider w1 being VECTOR of l0 such that
  A4: v1+w1 = 0.l0 by ALGSTR_0:def 11;
  reconsider w = w1 as VECTOR of l;
  take w;
  thus v+w = 0.l by A4;
  end;
A5: for v being VECTOR of l holds 1*v = v
  proof
  let v be VECTOR of l;
  reconsider v1 = v as VECTOR of l0;
  thus 1*v = 1*v1
          .= v by RLVECT_1:def 8;
  end;
A6: for a, b being Real
    for v being VECTOR of l holds (a*b)*v = a*(b*v)
  proof
  let a, b be Real;
  let v be VECTOR of l;
  reconsider v1 = v as VECTOR of l0;
  thus (a*b)*v = (a*b)*v1
              .= a*(b*v1) by RLVECT_1:def 7
              .= a*(b*v);
  end;
A7: for a, b being Real
    for v being VECTOR of l holds (a+b)*v = (a*v)+(b*v)
  proof
  let a, b be Real;
  let v be VECTOR of l;
  reconsider v1 = v as VECTOR of l0;
  thus (a+b)*v = (a+b)*v1
              .= (a*v1)+(b*v1) by RLVECT_1:def 6
              .= (a*v)+(b*v);
  end;
A8: for a being Real
    for v, w being VECTOR of l holds a*(v+w) = (a*v)+(a*w)
  proof
  let a be Real;
  let v, w be VECTOR of l;
  reconsider v1 = v, w1 = w as VECTOR of l0;
  thus a*(v+w) = a*(v1+w1)
              .= (a*v1)+(a*w1) by RLVECT_1:def 5
              .= (a*v)+(a*w);
  end;
A9:l is add-associative
  proof
  let u, v, w be VECTOR of l;
  reconsider u1 = u, v1 = v, w1 = w as VECTOR of l0;
  thus (u+v)+w = (u1+v1)+w1
              .= u1+(v1+w1) by RLVECT_1:def 3
              .= u+(v+w);
  end;
now
  let x, y be Point of l;
  let a be Real;
  reconsider u = x, w = y as VECTOR of l0;
  ||.u.|| = 0 iff u =0.l0 by NORMSP_0:def 5,def 6;
  hence ||.x.|| = 0 iff x = 0.l;
  thus ||.(a * x).|| = ||.(a * u).||
                    .= |.a.| * ||.u.|| by NORMSP_1:def 1
                    .= |.a.| * ||.x.||;
  ||.(u + w).|| <= ||.u.|| + ||.w.|| by NORMSP_1:def 1;
  hence ||.(x + y).|| <= ||.x.|| + ||.y.||;
end; then
l is discerning reflexive RealNormSpace-like;
hence thesis by A1, A2, A3, A5, A6, A7, A8, A9,
                RLVECT_1:def 5, def 6, def 7, def 8;
end;
