reserve i,j,k,n,m,l,s,t for Nat;
reserve a,b for Real;
reserve F for real-valued FinSequence;
reserve z for Complex;
reserve x,y for Complex;
reserve r,s,t for natural Number;

theorem Th22:
  (t+1) choose (s+1) = (t choose (s+1)) + (t choose s)
proof
  per cases by XXREAL_0:1;
  suppose
A1: s<t;
    thus ((t+1) choose (s+1)) = (t choose (s+1)) + (t choose s)
    proof
      reconsider m1 = t-s as Element of NAT by A1,INT_1:5;
A2:   s+1<=t by A1,NAT_1:13;
      then reconsider m2 = t-(s+1) as Element of NAT by INT_1:5;
A3:   s+1<=t+1 by A1,XREAL_1:6;
      then reconsider m = (t+1)-(s+1) as Element of NAT by INT_1:5;
      (t choose (s+1)) = (t!)/(((s+1)!) * (m2!)) by A2,Def3;
      then
A4:   (t choose (s+1)) + (t choose s) = (t!)/(((s+1)!) * (m2!)) + (t!)/((s
      !) * (m1!)) by A1,Def3
        .= ((t!)*((s!)*(m1!))+(t!)*(((s+1)!)*(m2!)))/((((s+1)!)*(m2!))*((s!)
      *(m1!))) by XCMPLX_1:116
        .= (t!*((s!)*(m1!))+(t!)*(s!*(s+1)*(m2!)))/((((s+1)!)*(m2!))*((s!)*(
      m1!))) by Th15
        .= (s!*((t!)*((m1!)+(s+1)*(m2!))))/(s!*((m1!)*((s+1)!*(m2!))))
        .=(t!*(((m2+1)!)+(s+1)*(m2!)))/(m1!*((s+1)!*(m2!))) by XCMPLX_1:91
        .= (t!*((m2!)*(m2+1)+(m2!)*(s+1)))/(m1!*((s+1)!*(m2!))) by Th15
        .= (m2!*((t!)*((m2+1)+(s+1))))/(m2!*(((s+1)!)*(m1!)))
        .= ((t!)*(t-(s-(s+1))))/(((s+1)!)*(m1!)) by XCMPLX_1:91
        .= ((t+1)!)/(((s+1)!)*(m1!)) by Th15;
      m = m1;
      hence thesis by A4,A3,Def3;
    end;
  end;
  suppose
A5: s=t;
    then s<t+1 by NAT_1:13;
    then
A6: t choose (s+1)=0 by A5,Def3;
    (t+1) choose (s+1)=1 by A5,Th21;
    hence thesis by A5,A6,Th21;
  end;
  suppose
A7: s>t;
    then s+1 >t+1 by XREAL_1:8;
    then
A8: (t+1) choose (s+1)=0 by Def3;
A9: s+1>t+0 by A7,XREAL_1:8;
    t choose s =0 by A7,Def3;
    hence thesis by A9,A8,Def3;
  end;
end;
