reserve PM for MetrStruct;
reserve x,y for Element of PM;
reserve r,p,q,s,t for Real;
reserve T for TopSpace;
reserve A for Subset of T;
reserve T for non empty TopSpace;
reserve x for Point of T;
reserve Z,X,V,W,Y,Q for Subset of T;
reserve FX for Subset-Family of T;
reserve a for set;
reserve x,y for Point of T;
reserve A,B for Subset of T;
reserve FX,GX for Subset-Family of T;

theorem
  T is compact implies T is paracompact
proof
  assume
A1: T is compact;
  for FX st FX is Cover of T & FX is open ex GX st GX is open & GX is
  Cover of T & GX is_finer_than FX & GX is locally_finite
  proof
    let FX;
    assume that
A2: FX is Cover of T and
A3: FX is open;
    consider GX such that
A4: GX c= FX and
A5: GX is Cover of T and
A6: GX is finite by A1,A2,A3;
    take GX;
    for W being Subset of T st W in GX holds W is open by A3,A4,TOPS_2:def 1;
    hence GX is open by TOPS_2:def 1;
    thus GX is Cover of T by A5;
    thus GX is_finer_than FX by A4,SETFAM_1:12;
    thus thesis by A6,Th10;
  end;
  hence thesis;
end;
