reserve D for set;
reserve x,x0,x1,x2,y,y0,y1,y2,z,z0,z1,z2,r,s,t for Real;
reserve p,a,u,u0 for Element of REAL 3;
reserve n,m,k for Element of NAT;
reserve f,f1,f2,f3,g for PartFunc of REAL 3,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem
  f is_partial_differentiable`1_on D implies
  D c= dom f & for u st u in D holds f is_partial_differentiable_in u,1
proof
    assume
A1: f is_partial_differentiable`1_on D;
    hence D c= dom f;
    set g = f|D;
    let u0 be Element of REAL 3;
    assume u0 in D;then
 g is_partial_differentiable_in u0,1 by A1;
    then consider x0,y0,z0 being Real such that
A2: u0 = <*x0,y0,z0*> & ex N being Neighbourhood of x0
    st N c= dom SVF1(1,g,u0) & ex L,R st for x st x in N holds
    SVF1(1,g,u0).x - SVF1(1,g,u0).x0 = L.(x-x0) + R.(x-x0) by Th13;
    consider N being Neighbourhood of x0 such that
A3: N c= dom SVF1(1,g,u0) & ex L,R st for x st x in N holds
    SVF1(1,g,u0).x - SVF1(1,g,u0).x0 = L.(x-x0) + R.(x-x0) by A2;
    for x st x in dom SVF1(1,g,u0) holds x in dom SVF1(1,f,u0)
    proof
      let x;
      assume x in dom SVF1(1,g,u0);
  then
A4: x in dom reproj(1,u0) & reproj(1,u0).x in dom (f|D) by FUNCT_1:11;
      dom (f|D) = dom f /\ D by RELAT_1:61;then
   dom (f|D) c= dom f by XBOOLE_1:17;
      hence thesis by A4,FUNCT_1:11;
    end;
    then for x be object st x in dom SVF1(1,g,u0) holds x in dom SVF1(1,f,u0);
    then dom SVF1(1,g,u0) c= dom SVF1(1,f,u0);then
A5: N c= dom SVF1(1,f,u0) by A3;
    consider L,R such that
A6: for x st x in N holds SVF1(1,g,u0).x - SVF1(1,g,u0).x0 =
    L.(x-x0) + R.(x-x0) by A3;
    for x st x in N holds SVF1(1,f,u0).x - SVF1(1,f,u0).x0 =
      L.(x-x0) + R.(x-x0)
    proof
      let x;
      assume
 A7: x in N;
 A8: for x st x in dom (SVF1(1,g,u0)) holds SVF1(1,g,u0).x = SVF1(1,f,u0).x
      proof
        let x;
        assume
   A9: x in dom (SVF1(1,g,u0));
   then
A10: x in dom reproj(1,u0) & reproj(1,u0).x in dom (f|D) by FUNCT_1:11;
        SVF1(1,g,u0).x = (f|D).(reproj(1,u0).x) by A9,FUNCT_1:12
        .= f.(reproj(1,u0).x) by A10,FUNCT_1:47
        .= SVF1(1,f,u0).x by A10,FUNCT_1:13;
        hence thesis;
      end;
 A11: x0 in N by RCOMP_1:16;
      L.(x-x0) + R.(x-x0) = SVF1(1,g,u0).x - SVF1(1,g,u0).x0 by A6,A7
      .= SVF1(1,f,u0).x - SVF1(1,g,u0).x0 by A3,A7,A8
      .= SVF1(1,f,u0).x - SVF1(1,f,u0).x0 by A3,A8,A11;
      hence thesis;
    end;
    hence thesis by A2,A5,Th13;
end;
