reserve K for Ring,
  V1,W1 for VectSp of K;
reserve F for Field,
  V,W for VectSp of F;
reserve T for linear-transformation of V,W;

theorem Th22:
  for A being Subset of V, B being Basis of V st A is Basis of ker
  T & A c= B holds T|(B \ A) is one-to-one
proof
  let A be Subset of V, B be Basis of V such that
A1: A is Basis of ker T and
A2: A c= B;
  reconsider A9 = A as Subset of V;
  set f = T|(B \ A);
  let x1,x2 be object such that
A3: x1 in dom f and
A4: x2 in dom f and
A5: f.x1 = f.x2 and
A6: x1 <> x2;
  x2 in dom T by A4,RELAT_1:57;
  then reconsider x2 as Element of V;
  x1 in dom T by A3,RELAT_1:57;
  then reconsider x1 as Element of V;
A7: x1 in B \ A by A3;
A8: not x1 in (A9 \/ {x2})
  proof
    assume
A9: x1 in A9 \/ {x2};
    per cases by A9,XBOOLE_0:def 3;
    suppose
      x1 in A9;
      hence contradiction by A7,XBOOLE_0:def 5;
    end;
    suppose
      x1 in {x2};
      hence contradiction by A6,TARSKI:def 1;
    end;
  end;
A10: x2 in B \ A by A4;
  then
A11: f.x2 = T.x2 by FUNCT_1:49;
  reconsider A as Basis of ker T by A1;
A12: ker T = Lin A by VECTSP_7:def 3;
  f.x1 = T.x1 by A7,FUNCT_1:49;
  then x1 - x2 in ker T by A5,A11,Th17;
  then x1 - x2 in Lin A9 by A12,VECTSP_9:17;
  then
A13: x1 in Lin (A9 \/ {x2}) by Th18;
  {x2} \/ {x1} = {x1,x2} by ENUMSET1:1;
  then
A14: (A9 \/ {x2}) \/ {x1} = A9 \/ {x1,x2} by XBOOLE_1:4;
  {x1,x2} c= B
  proof
    let z be object such that
A15: z in {x1,x2};
    per cases by A15,TARSKI:def 2;
    suppose
      z = x1;
      hence thesis by A7,XBOOLE_0:def 5;
    end;
    suppose
      z = x2;
      hence thesis by A10,XBOOLE_0:def 5;
    end;
  end;
  then
A16: A9 \/ {x1,x2} c= B by A2,XBOOLE_1:8;
  B is linearly-independent by VECTSP_7:def 3;
  hence thesis by A13,A14,A8,A16,Th21,VECTSP_7:1;
end;
