reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th22:
  v in Af & Af\{v} is non empty implies (center_of_mass V).Af =
        (1-1/card Af) * (center_of_mass V)/.(Af\{v}) + 1/card Af*v
  proof
    set Av=Af\{v};
    assume that
    A1: v in Af and
    A2: Av is non empty;
    consider L3 be Linear_Combination of{v} such that
    A3: L3.v=jj/card Af by RLVECT_4:37;
    consider L1 be Linear_Combination of Av such that
    A4: Sum L1=1/card Av*Sum Av and
    sum L1=1/card Av*card Av and
    A5: L1=(ZeroLC V)+*(Av-->1/card Av) by Th15;
    consider L2 be Linear_Combination of Af such that
    A6: Sum L2=1/card Af*Sum Af and
    sum L2=1/card Af*card Af and
    A7: L2=(ZeroLC V)+*(Af-->1/card Af) by Th15;
    A8: Sum L1=(center_of_mass V).Av by A2,A4,Def2;
    for u be Element of V holds L2.u=((1-1/card Af)*L1+L3).u
    proof
      let u be Element of V;
      A9: ((1-1/card Af)*L1+L3).u=((1-1/card Af)*L1).u+L3.u &
        ((1-1/card Af)*L1).u=(1-1/card Af)*(L1.u) by RLVECT_2:def 10,def 11;
      A10: ZeroLC(V).u=0 by RLVECT_2:20;
      A11: Carrier L3 c={v} by RLVECT_2:def 6;
      A12: dom(Af-->1/card Af)=Af;
      A13: dom(Av-->1/card Av)=Av;
      per cases;
      suppose A14: not u in Af;
        then not u in Carrier L3 by A1,A11,TARSKI:def 1;
        then A15: L3.u=0;
        not u in Av by A14,ZFMISC_1:56;
        then L1.u=0 by A5,A10,A13,FUNCT_4:11;
        hence thesis by A7,A9,A10,A12,A14,A15,FUNCT_4:11;
      end;
      suppose A16: v=u;
        then not u in Av by ZFMISC_1:56;
        then A17: L1.u=0 by A5,A10,A13,FUNCT_4:11;
        L2.u=(Af-->1/card Af).v by A1,A7,A12,A16,FUNCT_4:13;
        hence thesis by A1,A3,A9,A16,A17,FUNCOP_1:7;
      end;
      suppose A18: u in Af & u<>v;
        then L2.u=(Af-->1/card Af).u by A7,A12,FUNCT_4:13;
        then A19: L2.u=1/card Af by A18,FUNCOP_1:7;
        not u in Carrier L3 by A11,A18,TARSKI:def 1;
        then A20: L3.u=0;
        (not v in Av) & Av\/{v}=Af by A1,ZFMISC_1:56,116;
        then A21: card Af=card Av+1 by CARD_2:41;
        1-1/card Af=card Af/card Af-1/card Af by A1,XCMPLX_1:60
        .=(card Af-1)/card Af by XCMPLX_1:120
        .=card Av/card Af by A21;
        then A22: (1-1/card Af)*(1/card Av) = card Av/card Af/card Av
             by XCMPLX_1:99
          .=card Av/card Av/card Af by XCMPLX_1:48
          .=1/card Af by A2,XCMPLX_1:60;
        A23: u in Av by A18,ZFMISC_1:56;
        then L1.u=(Av-->1/card Av).u by A5,A13,FUNCT_4:13;
        hence thesis by A9,A19,A20,A22,A23,FUNCOP_1:7;
      end;
    end;
    then A24: L2=(1-1/card Af)*L1+L3;
    dom(center_of_mass V)=BOOL the carrier of V by FUNCT_2:def 1;
    then A25: Av in dom(center_of_mass V) by A2,ZFMISC_1:56;
    Sum L2=(center_of_mass V).Af by A1,A6,Def2;
    hence (center_of_mass V).Af=Sum((1-1/card Af)*L1)+Sum L3 by A24,RLVECT_3:1
    .=(1-1/card Af)*Sum L1+Sum L3 by RLVECT_3:2
    .=(1-1/card Af)*Sum L1+1/card Af*v by A3,RLVECT_2:32
    .=(1-1/card Af)*(center_of_mass V)/.Av+1/card Af*v
        by A8,A25,PARTFUN1:def 6;
  end;
