reserve n for Nat,
  a,b,c,d for Real,
  s for Real_Sequence;

theorem
  (for n holds s.n = n!*n+n/((n+1)!)) implies for n st n>=1 holds
  Partial_Sums(s).n = (n+1)!-1/((n+1)!)
proof
  defpred X[Nat] means Partial_Sums(s).$1= ($1+1)!-1/(($1+1)!);
  assume
A1: for n holds s.n = n!*n+n/((n+1)!);
  then
A2: s.0 = 0!*0+0/((0+1)!) .= 0;
A3: for n be Nat st n>=1 & X[n] holds X[n+1]
  proof
    let n be Nat;
    assume that
    n>=1 and
A4: Partial_Sums(s).n = (n+1)!-1/((n+1)!);
    Partial_Sums(s).(n+1)= (n+1)!-1/((n+1)!)+ s.(n+1) by A4,SERIES_1:def 1
      .= (n+1)!-1/((n+1)!) +((n+1)!*(n+1)+(n+1)/((n+1+1)!)) by A1
      .= (n+1)!+(n+1)!*(n+1)-1/((n+1)!) +(n+1)/((n+1+1)!)
      .=(n+1)!*(n+1+1)-(1*(n+2))/(((n+1)!)*(n+1+1))+(n+1)/((n+2)!) by
XCMPLX_1:91
      .=(n+1)!*(n+1+1)-(1*(n+2))/((n+1+1)!)+(n+1)/((n+2)!) by NEWTON:15
      .=(n+1)!*(n+1+1)-((n+2)/((n+1+1)!)-(n+1)/((n+2)!))
      .=(n+1)!*(n+1+1)-((n+2)-(n+1))/((n+2)!) by XCMPLX_1:120
      .=(n+1+1)!-1/((n+1+1)!) by NEWTON:15;
    hence thesis;
  end;
  Partial_Sums(s).(1+0)=Partial_Sums(s).0+s.(1+0) by SERIES_1:def 1
    .=0+s.1 by A2,SERIES_1:def 1
    .= 1!*1+1/((1+1)!) by A1
    .= (1+1)!-1+1-1/((1+1)!) by NEWTON:13,14;
  then
A5: X[1];
  for n be Nat st n>=1 holds X[n] from NAT_1:sch 8(A5,A3);
  hence thesis;
end;
