reserve P for Subset of TOP-REAL 2,
  f,f1,f2,g for FinSequence of TOP-REAL 2,
  p,p1,p2,q,q1,q2 for Point of TOP-REAL 2,
  r1,r2,r19,r29 for Real,
  i,j,k,n for Nat;

theorem Th22:
  L~f = L~(Rev f)
proof
  defpred P[FinSequence of TOP-REAL 2] means L~$1 = L~(Rev $1);
A1: for f,p st P[f] holds P[f^<*p*>]
  proof
    let f,p such that
A2: P[f];
    per cases;
    suppose
A3:   f is empty;
      hence L~(f^<*p*>) = L~<*p*> by FINSEQ_1:34
        .= L~(Rev <*p*>) by FINSEQ_5:60
        .= L~(Rev(f^<*p*>)) by A3,FINSEQ_1:34;
    end;
    suppose
A4:   f is non empty;
      set q9 = (Rev f)/.1;
      set q = f/.len f;
      len f = len Rev f by FINSEQ_5:def 3;
      then
A5:   Rev f is non empty by A4;
      q = q9 by A4,FINSEQ_5:65;
      hence L~(f^<*p*>) = LSeg(p,q9) \/ L~(Rev f) by A2,A4,Th19
        .= L~(<*p*>^(Rev f)) by A5,Th20
        .= L~(Rev(f^<*p*>)) by FINSEQ_5:63;
    end;
  end;
A6: P[<*>(the carrier of TOP-REAL 2)];
  for f holds P[f] from FINSEQ_2:sch 2(A6,A1);
  hence thesis;
end;
