reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem
  for A being Subset of M holds A <> {} & A is bounded & diameter A = 0
  implies ex g being Point of M st A = {g}
proof
  let A be Subset of M;
  assume that
A1: A <> {} and
A2: A is bounded;
  thus diameter A = 0 implies ex g being Point of M st A = {g}
  proof
    set g = the Element of A;
    reconsider g as Element of M by A1,TARSKI:def 3;
    assume
A3: diameter A = 0;
    reconsider Z = {g} as Subset of M;
    take g;
    for x being Element of M holds x in A iff x in Z
    proof
      let x be Element of M;
      thus x in A implies x in Z
      proof
        assume x in A;
        then dist(x,g)<=0 by A2,A3,Def8;
        then dist(x,g) = 0 by METRIC_1:5;
        then x = g by METRIC_1:2;
        hence thesis by TARSKI:def 1;
      end;
      assume
A4:   x in Z;
      g in A by A1;
      hence thesis by A4,TARSKI:def 1;
    end;
    hence thesis by SUBSET_1:3;
  end;
end;
