reserve X for set,
        D for a_partition of X,
        TG for non empty TopologicalGroup;
reserve A for Subset of X;
reserve US for UniformSpace;

theorem Th11:
  for MS being PseudoMetricSpace holds
  Family_open_set(FMT_induced_by(uniformity_induced_by(MS))) =
    Family_open_set MS
  proof
    let MS be PseudoMetricSpace;
    set X = Family_open_set(FMT_induced_by(uniformity_induced_by(MS))),
        Y = Family_open_set MS;
    thus X c= Y
    proof
      let t be object;
      assume
A2:   t in X;
      then reconsider t1 = t as Subset of
        FMT_induced_by(uniformity_induced_by(MS));
      for x being Point of MS st x in t1 holds ex r being Real st r>0 &
        Ball(x,r) c= t1
      proof
        let x be Point of MS;
        assume
A3:     x in t1;
        reconsider x1 = x as Element of uniformity_induced_by(MS);
        t1 in Neighborhood x1 by A3,A2,Th8,Th9;
        then consider V0 be Element of the entourages of
        uniformity_induced_by(MS) such that
A4:     t1 = Neighborhood(V0,x1);
        consider b be Element of fundamental_system_of_entourages(MS) such that
A5:     b c= V0 by CARDFIL2:def 8;
        b in the set of all fundamental_element_of_entourages(MS,r) where
          r is positive Real;
        then consider r0 be positive Real such that
A6:     b = fundamental_element_of_entourages(MS,r0);
        now
          take r0;
          thus r0 > 0;
          thus Ball(x,r0) c= t1
          proof
            let u be object;
            assume
A7:         u in Ball(x,r0);
            then reconsider u1 = u as Element of MS;
            dist(x,u1) < r0 by A7,METRIC_1:11;
            then [x,u1] in b by A6;
            hence thesis by A4,A5;
          end;
        end;
        hence thesis;
      end;
      hence thesis by PCOMPS_1:def 4;
    end;
    let t be object;
    assume
A8: t in Y;
    then reconsider t1 = t as Subset of MS;
    for x be Element of uniformity_induced_by(MS) st x in t1 holds
      t1 in Neighborhood x
    proof
      let x be Element of uniformity_induced_by(MS);
      assume
A9:   x in t1;
      reconsider x1 = x as Element of MS;
      consider r0 be Real such that
A10:  r0 > 0 and
A11:  Ball(x1,r0) c= t1 by A8,PCOMPS_1:def 4,A9;
      reconsider r1 = r0 / 2 as positive Real by A10;
      set V0 = fundamental_element_of_entourages(MS,r1);
      V0 in fundamental_system_of_entourages(MS);
      then reconsider V0 as Element of fundamental_system_of_entourages(MS);
      reconsider V1 = V0 \/ [:t1,t1:] as Subset of
        [:the carrier of MS,the carrier of MS:];
      V0 c= V1 by XBOOLE_1:7;
      then reconsider V1 as Element of the entourages of
        uniformity_induced_by(MS) by CARDFIL2:def 8;
      set Z = {y where y is Element of
        uniformity_induced_by(MS): [x,y] in V1};
      Z = t1
      proof
        thus Z c= t1
        proof
          let u be object;
          assume u in Z;
          then consider y0 be Element of
            uniformity_induced_by(MS) such that
A13:      u = y0 and
A14:      [x,y0] in V1;
          per cases by A14,XBOOLE_0:def 3;
          suppose [x,y0] in V0;
            then consider x2,y2 be Element of MS such that
A15:        [x,y0] = [x2,y2] and
A16:        dist(x2,y2) <= r1;
            r0 / 2 < r0 / 1 by A10,XREAL_1:76; then
A17:        dist(x2,y2) < r0 by A16,XXREAL_0:2;
            Ball(x2,r0) = Ball(x1,r0) by A15,XTUPLE_0:1;
            then y2 in t1 by A17,METRIC_1:11,A11;
            hence thesis by A13,A15,XTUPLE_0:1;
          end;
          suppose [x,y0] in [:t1,t1:];
            then ex a,b be object st a in t1 & b in t1 & [x,y0] = [a,b]
              by ZFMISC_1:def 2;
            hence thesis by A13,XTUPLE_0:1;
          end;
        end;
        let v be object;
        assume
A18:    v in t1;
        then reconsider v1 = v as Element of uniformity_induced_by(MS);
        [x,v1] in [:t1,t1:] by A18,A9,ZFMISC_1:def 2;
        then [x,v1] in V1 by XBOOLE_0:def 3;
        hence thesis;
      end;
      then t1 = Neighborhood(V1,x);
      hence thesis;
    end;
    hence thesis by Th8,Th9;
  end;
