
theorem
  for T1, T2 being TopSpace, S1 being Subset of T1, S2 being Subset of
T2 st S1 is compact & S2 is compact holds [:S1, S2:] is compact Subset of [:T1,
  T2:]
proof
  let T1, T2 be TopSpace, S1 be Subset of T1, S2 be Subset of T2;
  assume that
A1: S1 is compact and
A2: S2 is compact;
  per cases;
  suppose
A3: S1 is non empty & S2 is non empty;
    then (ex x be object st x in S1 )& ex y be object st y in S2;
    then reconsider T1, T2 as non empty TopSpace;
    reconsider S2 as compact non empty Subset of T2 by A2,A3;
    reconsider S1 as compact non empty Subset of T1 by A1,A3;
    reconsider X = [:S1, S2:] as Subset of [:T1, T2:];
    the TopStruct of [:T1|S1, T2|S2:] = the TopStruct of ([:T1, T2:] | X)
    by Th22;
    hence thesis by COMPTS_1:3;
  end;
  suppose
    S1 is empty & S2 is non empty;
    then reconsider S1 as empty Subset of T1;
    [:S1, S2:] = {}([:T1, T2:]);
    hence thesis;
  end;
  suppose
    S1 is non empty & S2 is empty;
    then reconsider S2 as empty Subset of T2;
    [:S1, S2:] = {}([:T1, T2:]);
    hence thesis;
  end;
  suppose
    S1 is empty & S2 is empty;
    then reconsider S2 as empty Subset of T2;
    [:S1, S2:] = {}([:T1, T2:]);
    hence thesis;
  end;
end;
