
theorem Th23:
  { p where p is Point of [:R^1,R^1:] : p`2 >= 1 - 2 * (p`1) & p`2
  >= 2 * (p`1) - 1 } is closed Subset of [:R^1,R^1:]
proof
  set GG = [:R^1,R^1:], SS = TOP-REAL 2;
  defpred P[Point of GG] means $1`2 >= 1 - 2 * ($1`1) & $1`2 >= 2 * ($1`1) - 1;
  defpred R[Point of SS] means $1`2 >= 1 - 2 * ($1`1) & $1`2 >= 2 * ($1`1) - 1;
  reconsider K = { p where p is Point of GG : P[p] } as Subset of GG from
  DOMAIN_1:sch 7;
  reconsider L = { p where p is Point of SS : R[p] } as Subset of SS from
  DOMAIN_1:sch 7;
  consider f being Function of GG, SS such that
A1: for x, y being Real holds f. [x,y] = <*x,y*> by Th20;
A2: L c= f .: K
  proof
    let x be object;
    assume x in L;
    then consider z being Point of SS such that
A3: z = x and
A4: R[z];
    the carrier of SS = REAL 2 by EUCLID:22;
    then z is Tuple of 2,REAL by FINSEQ_2:131;
    then consider x1, y1 being Element of REAL such that
A5: z = <*x1, y1*> by FINSEQ_2:100;
    z`1 = x1 by A5,EUCLID:52;
    then
A6: y1 >= 1 - 2 * x1 & y1 >= 2 * x1 - 1 by A4,A5,EUCLID:52;
    set Y = [x1, y1];
A7: Y in [:the carrier of R^1, the carrier of R^1:] by TOPMETR:17,ZFMISC_1:87;
    then
A8: Y in the carrier of GG by BORSUK_1:def 2;
    reconsider Y as Point of GG by A7,BORSUK_1:def 2;
A9: Y in dom f by A8,FUNCT_2:def 1;
    Y`1 = x1 & Y`2 = y1;
    then
A10: Y in K by A6;
    x = f.Y by A1,A3,A5;
    hence thesis by A10,A9,FUNCT_1:def 6;
  end;
A11: f is being_homeomorphism by A1,TOPREAL6:76;
  f .: K c= L
  proof
    let x be object;
    assume x in f .: K;
    then consider y being object such that
    y in dom f and
A12: y in K and
A13: x = f.y by FUNCT_1:def 6;
    consider z being Point of GG such that
A14: z = y and
A15: P[z] by A12;
    z in the carrier of GG;
    then z in [:the carrier of R^1, the carrier of R^1:] by BORSUK_1:def 2;
    then consider x1, y1 being object such that
A16: x1 in the carrier of R^1 & y1 in the carrier of R^1 and
A17: z = [x1, y1] by ZFMISC_1:def 2;
    reconsider x1, y1 as Real by A16;
A18: x = |[ x1, y1 ]| by A1,A13,A14,A17;
    then reconsider x9 = x as Point of SS;
A19: z`1 = x1 & z`2 = y1 by A17;
    x9`1 = x1 & x9`2 = y1 by A18,FINSEQ_1:44;
    hence thesis by A15,A19;
  end;
  then f .: K = L by A2;
  hence thesis by A11,Th19,TOPS_2:58;
end;
