
theorem Th23:
  for X be non empty TopSpace
  for f,g be RealMap of X holds
    support(f+g) c= support(f) \/ support(g)
proof
  let X be non empty TopSpace;
  let f,g be RealMap of X;
  set CX= the carrier of X;
  reconsider h=f+g as RealMap of X;
A1:dom f = CX & dom g = CX & dom h = CX by FUNCT_2:def 1;
  now let x be object;
    assume A2:x in (CX\ support(f)) /\ (CX\ support(g)); then
    x in (CX\ support(f)) & x in (CX\ support(g)) by XBOOLE_0:def 4; then
    x in CX & not x in support(f) & x in CX & not x in support(g)
                                        by XBOOLE_0:def 5; then
A3: x in CX & f.x =0 & g.x=0 by PRE_POLY:def 7;
A4: (f+g).x = 0 + 0 by A3,VALUED_1:1;
    not x in support(f+g) by A4,PRE_POLY:def 7;
    hence x in CX\ support(f+g) by A2,XBOOLE_0:def 5;
  end; then
  (CX\ support(f)) /\ (CX \ support(g)) c= CX\ support(f+g);
  then
  CX\ ( support(f) \/ support(g) ) c= CX\ support(f+g) by XBOOLE_1:53;
  then
  CX\ (CX\ support(f+g)) c=CX\ (CX\ (support(f) \/ support(g)))
                                               by XBOOLE_1:34; then
  CX/\ support(f+g) c=CX\ (CX\ (support(f) \/ support(g))) by XBOOLE_1:48;
  then
  CX/\ support(f+g) c= CX/\ (support(f) \/ support(g)) by XBOOLE_1:48;
  then support(f+g) c= CX/\ (support(f) \/ support(g))
    by A1,PRE_POLY:37,XBOOLE_1:28; then
  support(f+g) c= (CX/\ support(f)) \/ (CX/\ support(g)) by XBOOLE_1:23;
  then support(f+g) c= support(f) \/ (CX/\ support(g))
    by A1,PRE_POLY:37,XBOOLE_1:28;
  hence thesis by A1,PRE_POLY:37,XBOOLE_1:28;
end;
