reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem
  seq is convergent & (ex k st seq=seq1 ^\k) implies lim seq1 =lim seq
proof
  assume that
A1: seq is convergent and
A2: ex k st seq=seq1 ^\k;
  consider k such that
A3: seq=seq1 ^\k by A2;
A4: now
    let p;
    assume 0<p;
    then consider n1 such that
A5: for m st n1<=m holds |.seq.m-(lim seq).|<p by A1,COMSEQ_2:def 6;
    take n=n1+k;
    let m;
    assume
A6: n<=m;
    then consider l being Nat such that
A7: m=n1+k+l by NAT_1:10;
    reconsider l as Element of NAT by ORDINAL1:def 12;
    m-k=n1+l+k+-k by A7;
    then consider m1 such that
A8: m1=m-k;
    now
      assume not n1<=m1;
      then m1+k<n1+k by XREAL_1:6;
      hence contradiction by A6,A8;
    end;
    then
A9: |.seq.m1-(lim seq).|<p by A5;
    m1+k=m by A8;
    hence |.seq1.m-(lim seq).|<p by A3,A9,NAT_1:def 3;
  end;
  seq1 is convergent by A1,A2,Th22;
  hence thesis by A4,COMSEQ_2:def 6;
end;
