reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th23:
  for T being non empty TopSpace for F be Subset-Family of T for S
  be SetSequence of T st rng S c= F & S is non-empty ex R be non-empty closed
  SetSequence of T st R is non-ascending & ( F is locally_finite & S is
  one-to-one implies meet R = {} ) & for i ex Si be Subset-Family of T st R.i =
  Cl union Si & Si = {S.j where j is Element of NAT: j >= i}
proof
  let T being non empty TopSpace;
  let F be Subset-Family of T;
  let S be SetSequence of T such that
A1: rng S c= F and
A2: S is non-empty;
  defpred r[object,object] means
  for i st i=$1 ex SS be Subset-Family of T st SS c=
  F & SS = {S.j where j is Element of NAT:j >= i} & $2=Cl(union SS);
A3: for x being object st x in NAT
ex y being object st y in bool(the carrier of T) & r[x,y]
  proof
    let x be object;
    assume x in NAT;
    then reconsider x9=x as Nat;
    set SS={S.j where j is Element of NAT:j >= x9};
    SS c= bool(the carrier of T)
    proof
      let y be object;
      assume y in SS;
      then ex j be Element of NAT st S.j=y & j>=x9;
      hence thesis;
    end;
    then reconsider SS as Subset-Family of T;
    take Cl union SS;
    SS c= F
    proof
      let y be object;
      assume y in SS;
      then consider  j be Element of NAT such that
A4:    S.j=y & j>=x9;
      dom S=NAT by FUNCT_2:def 1;
      then y in rng S by A4,FUNCT_1:def 3;
      hence thesis by A1;
    end;
    hence thesis;
  end;
  consider R be SetSequence of T such that
A5: for x being object st x in NAT holds r[x,R.x] from FUNCT_2:sch 1(A3);
A6: now
    let n be object;
    assume n in dom R;
    then reconsider n9=n as Element of NAT;
A7: S.n9 c= Cl(S.n9) by PRE_TOPC:18;
    consider SS be Subset-Family of T such that
    SS c= F and
A8: SS = {S.j where j is Element of NAT:j>=n9} and
A9: R.n9=Cl(union SS) by A5;
    S.n9 in SS by A8;
    then
A10: Cl(S.n9) c= Cl(union SS) by PRE_TOPC:19,ZFMISC_1:74;
    dom S=NAT by FUNCT_2:def 1;
    hence R.n is non empty by A2,A9,A7,A10,FUNCT_1:def 9;
  end;
  now
    let n;
    reconsider n9=n as Element of NAT by ORDINAL1:def 12;
    ex SS be Subset-Family of T st SS c= F & SS = {S.j where j is Element
    of NAT:j>=n9} & R.n9=Cl(union SS) by A5;
    hence R.n is closed;
  end;
  then reconsider R as non-empty closed SetSequence of T by A6,Def6,
FUNCT_1:def 9;
  take R;
  now
    let n be Nat;
A11:  n in NAT by ORDINAL1:def 12;
    consider Sn be Subset-Family of T such that
    Sn c= F and
A12: Sn = {S.j where j is Element of NAT:j>=n} and
A13: R.n=Cl(union Sn) by A5,A11;
    consider Sn1 be Subset-Family of T such that
    Sn1 c= F and
A14: Sn1 = {S.j where j is Element of NAT:j>=n+1} and
A15: R.(n+1)=Cl(union Sn1) by A5;
    Sn1 c= Sn
    proof
      let y be object;
      assume y in Sn1;
      then consider j be Element of NAT such that
A16:  y=S.j and
A17:  j>=n+1 by A14;
      j>=n by A17,NAT_1:13;
      hence thesis by A12,A16;
    end;
    then union Sn1 c= union Sn by ZFMISC_1:77;
    hence R.(n+1) c= R.n by A13,A15,PRE_TOPC:19;
  end;
  hence R is non-ascending by KURATO_0:def 3;
  thus F is locally_finite & S is one-to-one implies meet R = {}
  proof
A18: dom S=NAT by FUNCT_2:def 1;
    then reconsider rngS=rng S as non empty Subset-Family of T by RELAT_1:42;
    reconsider Sp=S as sequence of rngS by A18,FUNCT_2:1;
    assume that
A19: F is locally_finite and
A20: S is one-to-one;
    reconsider S9=Sp" as Function;
    reconsider S9 as Function of rngS,NAT by A20,FUNCT_2:25;
    deffunc s9(Element of rngS)=S9.$1;
    assume meet R <> {};
    then consider x being object such that
A21: x in meet R by XBOOLE_0:def 1;
    reconsider x as Point of T by A21;
    rng S is locally_finite by A1,A19,PCOMPS_1:9;
    then consider W be Subset of T such that
A22: x in W and
A23: W is open and
A24: { V where V is Subset of T: V in rngS & V meets W } is finite;
    set X={ V where V is Subset of T: V in rngS & V meets W };
    set Y={s9(z) where z is Element of rngS:z in X};
A25: Y is finite from FRAENKEL:sch 21(A24);
    Y c= NAT
    proof
      let y be object;
      assume y in Y;
      then ex z be Element of rngS st y =s9(z) & z in X;
      hence thesis;
    end;
    then reconsider Y as Subset of NAT;
    consider n be Nat such that
A26: for k be Nat st k in Y holds k <= n by A25,STIRL2_1:56;
    set n1=n+1;
A27: x in R.n1 by A21,KURATO_0:3;
    consider Sn be Subset-Family of T such that
A28: Sn c= F and
A29: Sn ={S.j where j is Element of NAT:j>=n1} and
A30: R.n1=Cl(union Sn) by A5;
    Cl(union Sn)=union(clf Sn) by A19,A28,PCOMPS_1:9,20;
    then consider CLF be set such that
A31: x in CLF and
A32: CLF in clf Sn by A30,A27,TARSKI:def 4;
    reconsider CLF as Subset of T by A32;
    consider U be Subset of T such that
A33: CLF = Cl U and
A34: U in Sn by A32,PCOMPS_1:def 2;
    consider j be Element of NAT such that
A35: U=S.j and
A36: j>=n1 by A29,A34;
A37: Sp.j in rngS;
    Sp.j meets W by A22,A23,A31,A33,A35,TOPS_1:12;
    then
A38: Sp.j in X by A37;
    (S").(S.j) = j by A20,FUNCT_2:26;
    then j in Y by A38;
    then j <=n by A26;
    hence thesis by A36,NAT_1:13;
  end;
  let i;
  i in NAT by ORDINAL1:def 12;
  then ex SS be Subset-Family of T st SS c= F & SS = {S.j where j is Element
  of NAT:j >= i} & R.i=Cl(union SS) by A5;
  hence thesis;
end;
