reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem
  for Fu being Subset-Family of GX st (for A being Subset of GX st A in
  Fu holds A is a_union_of_components of GX) holds union Fu is
  a_union_of_components of GX
proof
  let Fu be Subset-Family of GX;
  {B: ex B2 st B2 in Fu & B c= B2 & B is a_component} c= bool (the
  carrier of GX)
  proof
    let x be object;
    assume x in {B: ex B2 st B2 in Fu & B c= B2 & B is a_component};
    then ex B st x=B & ex B2 st B2 in Fu & B c= B2 & B is a_component;
    hence thesis;
  end;
  then reconsider
  F2={B: ex B2 st B2 in Fu & B c= B2 & B is a_component} as
  Subset-Family of GX;
A1: for B being Subset of GX st B in F2 holds B is a_component
  proof
    let B be Subset of GX;
    assume B in F2;
    then ex A2 being Subset of GX st B=A2 & ex B2 st B2 in Fu & A2 c= B2 & A2
    is a_component;
    hence thesis;
  end;
  assume
A2: for A being Subset of GX st A in Fu holds A is a_union_of_components of GX;
A3: union Fu c= union F2
  proof
    let x be object;
    assume x in union Fu;
    then consider X2 such that
A4: x in X2 and
A5: X2 in Fu by TARSKI:def 4;
    reconsider B3=X2 as Subset of GX by A5;
    B3 is a_union_of_components of GX by A2,A5;
    then consider F being Subset-Family of GX such that
A6: for B being Subset of GX st B in F holds B is a_component and
A7: B3=union F by Def2;
    consider Y2 such that
A8: x in Y2 and
A9: Y2 in F by A4,A7,TARSKI:def 4;
    reconsider A3=Y2 as Subset of GX by A9;
    A3 is a_component & Y2 c= B3 by A6,A7,A9,ZFMISC_1:74;
    then A3 in F2 by A5;
    hence thesis by A8,TARSKI:def 4;
  end;
  union F2 c= union Fu
  proof
    let x be object;
    assume x in union F2;
    then consider X such that
A10: x in X and
A11: X in F2 by TARSKI:def 4;
    ex B st X=B & ex B2 st B2 in Fu & B c= B2 & B is a_component by A11;
    hence thesis by A10,TARSKI:def 4;
  end;
  then union Fu = union F2 by A3;
  hence thesis by A1,Def2;
end;
