
theorem Th23: :: ABunion:
for R being with_finite_stability# RelStr, A being StableSet of R
 st card A = stability# R holds Upper A \/ Lower A = [#]R
proof
 let R be with_finite_stability# RelStr, A be StableSet of R such that
A1: card A = stability# R;
   set cP = the carrier of R;
   cP c= Upper A \/ Lower A proof
     let x be object;
     assume A2: x in cP;
     assume A3: not x in Upper A \/ Lower A;
      reconsider x as Element of cP by A2;
     A4: not x in Upper A by A3,XBOOLE_0:def 3;
     then A5: not x in A by XBOOLE_0:def 3;
     A6: not x in uparrow A by A4,XBOOLE_0:def 3;
      not x in Lower A by A3,XBOOLE_0:def 3;
     then A7: not x in downarrow A by XBOOLE_0:def 3;
       set Ax = A \/ {x};
       A8: {x} c= the carrier of R by A2,ZFMISC_1:31;
      now
         let a, b be Element of R such that
       A9: a in Ax and
       A10: b in Ax and
       A11: a <> b;
      per cases by A9,A10,XBOOLE_0:def 3;
      suppose a in A & b in A;
       hence not a <= b & not b <= a by A11,Def2;
      end;
      suppose A12: a in A & b in {x};
        then b = x by TARSKI:def 1;
     hence not a <= b & not b <= a by A6,A7,A12,WAYBEL_0:def 15,def 16;
      end;
      suppose A13: a in {x} & b in A;
        then a = x by TARSKI:def 1;
     hence not a <= b & not b <= a by A6,A7,A13,WAYBEL_0:def 15,def 16;
      end;
      suppose a in {x} & b in {x};
        then a = x & b = x by TARSKI:def 1;
       hence not a <= b & not b <= a by A11;
      end;
      end;
      then A14: Ax is StableSet of R by A8,Def2,XBOOLE_1:8;
       card Ax = card A + 1 by A5,CARD_2:41;
      then card Ax > card A by NAT_1:13;
    hence contradiction by Def6,A1,A14;
   end;
 hence Upper A \/ Lower A = [#]R;
end;
