reserve x,y,z for object,X,Y for set;
reserve N for e_net;

theorem Th23:
  id((the carrier of N) \ rng(the escape of N)) *
    ((the escape of N) \ id(the carrier of N)) =
    ((the escape of N) \ id(the carrier of N)) &
  id((the carrier of N) \ rng(the entrance of N)) *
    ((the entrance of N) \ id(the carrier of N)) =
    ((the entrance of N) \ id(the carrier of N))
proof
  set T = the entrance of N, C = the carrier of N;
  set E = the escape of N, I = id C;
  for x,y being object
holds [x,y] in (E \ I) implies [x,y] in (id(C \ rng E) * (E \ I))
  proof
    let x,y be object;
    assume
A1: [x,y] in (E \ I);
    then [x,y] in E by XBOOLE_0:def 5; then
A2: x in dom(E) by XTUPLE_0:def 12;
A3: not x in rng E
    proof
      assume x in rng E;
      then ex z being object st [z,x] in E by XTUPLE_0:def 13; then
      E * (E \ I) <> {} by A1,RELAT_1:def 8;
      hence thesis by Def2;
    end;
    dom E c= C by Th14;
    then x in (C \ rng E) by A2,A3,XBOOLE_0:def 5;
    then [x,x] in id(C \ rng E) by RELAT_1:def 10;
    hence thesis by A1,RELAT_1:def 8;
  end; then
A4: E \ I c= id(C \ rng E) * (E \ I) by RELAT_1:def 3;
  for x,y being object
holds [x,y] in (T \ I) implies [x,y] in (id(C \ rng T) * (T \ I))
  proof
    let x,y be object;
    assume
A5: [x,y] in (T \ I);
    then [x,y] in T by XBOOLE_0:def 5; then
A6: x in dom(T) by XTUPLE_0:def 12;
A7: not x in rng T
    proof
      assume x in rng T;
      then ex z being object st [z,x] in T by XTUPLE_0:def 13;
      then T * (T \ I) <> {} by A5,RELAT_1:def 8;
      hence thesis by Def2;
    end;
    dom T c= C by Th14;
    then x in (C \ rng T) by A6,A7,XBOOLE_0:def 5;
    then [x,x] in id(C \ rng T) by RELAT_1:def 10;
    hence thesis by A5,RELAT_1:def 8;
  end; then
A8: (T \ I) c= id(C \ rng T) * (T \ I) by RELAT_1:def 3;
  id(C \ rng E) * (E \ I) c= (E \ I) &
  id(C \ rng T) * (T \ I) c= (T \ I) by RELAT_1:50;
  hence thesis by A4,A8,XBOOLE_0:def 10;
end;
