reserve a,a1,a2,b,c,d for Ordinal,
  n,m,k for Nat,
  x,y,z,t,X,Y,Z for set;
reserve f,g for Function;
reserve A,B,C for array;

theorem Th23:
  dom A = a\b & A is non empty implies base-A = b & limit-A = a
  proof assume
A1: dom A = a\b & A is non empty;
    set x = the Element of dom A;
    dom A <> {} by A1; then
A2: x in a\b by A1;
A:  b c= x & x in a by A1,ORDINAL6:5;
    not b in b; then
A3: b in a & b nin b by A,ORDINAL1:12; then
    b in a\b by XBOOLE_0:def 5; then
A4: b in sup dom A by A1,ORDINAL2:19;
    A is b-based
    by A1,A3,ORDINAL6:5;
    hence base-A = b by Def4,A1,A2;
A5: a c= sup dom A
    proof
      let x be Ordinal; assume
A6:   x in a;
      per cases;
      suppose
        x in b;
        hence thesis by A4,ORDINAL1:10;
      end;
      suppose
        x nin b; then
        x in a\b by A6,XBOOLE_0:def 5;
        hence thesis by A1,ORDINAL2:19;
      end;
    end;
    sup dom A c= sup a by A1,ORDINAL2:22; then
    sup dom A c= a by ORDINAL2:18; then
    a = sup dom A by A5;
    hence thesis by Th16;
  end;
